How do you implement metric tensor in Mathematica?

Question

I'm trying to follow several tutorials on metric tensors. One of the common exercises is a polar metric. I'm stuck trying to implement this in Mathematica. According to the derivation, the polar metric is this:$$g_{\mu\nu}= \begin{bmatrix}1 & 0 & 0\\0 & r^2 & 0\\0 & 0 & r^2 sin^2\theta\end{bmatrix}$$So if I want to implement this in Mathematica, I have: $$g_{\mu\nu}[r_,\phi,\theta]:=\{\{1.,0.,0.\},\{0.,r^2,0.\},\{0.,0.,r^2 Sin^2[\theta]\}$$Now, my goal is to find $ds^2$, the distance between two points on this manifold using the formula $$ds^2=\sum_{i,j=1}^3 g_{\mu\nu}dx^idx^j$$ So I construct two random points. I know from another exercise that the distance between these two points is $\sqrt {17}$:

p1 = CoordinateTransformData["Cartesian" -> "Spherical", 
   "Mapping", {4., 2., -1.}];
p2 = CoordinateTransformData["Cartesian" -> "Spherical", 
   "Mapping", {7., 4., -3.}];

And this is where I'm stuck. How do I use $g_{\mu\nu}$ to calculation the distance between the two points? That is, I have an $r$ parameter in the metric, but I can only extract a $dr, d\theta, d\phi$ from the two points. Where do I find the values that go into the matrix ($r$ and $\theta$)?

Answer 1

Assuming we solved Euler's equations in a Cartesian system in a previous problem, we can parameterize the path through our points $q_1$ and $q_2$ as

q1 = {4, 2, -1};
q2 = {7, 4, -3};

x[t] = q1[[1]] + (q2[[1]] - q1[[1]]) t;
y[t] = q1[[2]] + (q2[[2]] - q1[[2]]) t; 
z[t] = q1[[3]] + (q2[[3]] - q1[[3]]) t;

where we are at $q_1$ at time $t=0$ and at $q_2$ at $t=1$. Now we transform the path to spherical coordinates $(r, \theta, \phi)$ with this

{r[t], θ[t], ϕ[t]} = 
 CoordinateTransformData["Cartesian" -> "Spherical", 
  "Mapping", {x[t], y[t], z[t]}]

Then the differentials are

g = {{1, 0, 0}, {0, r[t]^2, 0}, {0, 0, r[t]^2 Sin[θ[t]]^2}};

dx = D[{r[t], θ[t], ϕ[t]}, t]

ds2 = Dot[dx, g, dx]

Finally, integrate along the path to get the distance

dist = Integrate[Sqrt[ds2], {t, 0, 1}];
dist^2        (*  17  *)

Alternate Parameterization

Another way to parameterize the straight line path is

{x[t], y[t], z[t]} = q1 + (q2 - q1) λ[t];

Here we can think of $\lambda$ or $t$ as the parameter. One important thing is we are at $q_1$ when $\lambda(t_A)=0$ and we are at $q_2$ when $\lambda(t_B)=1$. So $\lambda$ is a parameter that goes from 0 to 1 along the path while $t$ goes from $t_A$ to $t_B$.

Another important thing is to use the same $\lambda(t)$ for x[t], y[t] and z[t] in order to stay on the straight line.

Following the same procedure as above we obtain

ds2 = Dot[dx, g, dx] // Simplify       (*  17 [λ]'[t]^2  *)

dist = Integrate[Sqrt[ds2] // PowerExpand, 
        {t, Subscript[t, A], Subscript[t, B]}];
dist // TeXForm

$$\int_{t_A}^{t_B} \sqrt{17} \lambda '(t) \, dt$$

The integral evaluates to $\sqrt{17}$ for any suitable $\lambda(t)$ that takes us to $q_1$ at $t=t_A$ and to $q_2$ at $t=t_B$.

We could also show that any $\lambda(t)$ is suitable by (1) evaluating

Needs["VariationalMethods`"]
EulerEquations[Sqrt[ds2], {λ[t]}, t]

(*  { True }  *)

and (2) stating the boundary conditions on $\lambda(t)$.

Answer 2

Not an answer, but an extended comment with formulas.

A possible misconception here is your assumption that $\mathrm{d} s^2$ were the distance between two points. That is just not true. The distance of two points $p_0$ and $p_1$ is

$$d(p_0,p_1) = \inf_\gamma L(\gamma),$$

where the infimum runs over all smooth curves $\gamma \colon [0,1] \to \mathbb{R}^n$ with $\gamma(0) =p_0$ and $\gamma(1) = p_1$ and where the curve length $L(\gamma)$ is given by

$$ L(\gamma) = \int_\gamma \mathrm{d}s := \int_0^1 \sqrt{g(\gamma(t)) (\gamma'(t) , \gamma'(t))} \, \mathrm{d} t.$$

So, $\mathrm{d}s^2$ does appear in the expression for curve length, but for computing $d(p_0,p_1)$ one has also to minimize the expression $L(\gamma)$. That is in general quite a nontrivial task.