recurrence equation

Question

The output of Mathematica is only a copy of the input. What am I doing wrong?

RSolve[r1[(n + 1)*t] == 1/2 (r1[n*t] + 
r4[n*t] + (r1[n*t] - r4[n*t]) Cosh[
  2 (-1 + n)* t] + (-r2[n*t] + r3[n*t]) Sinh[2 t - 2 n *t]),r2[(n + 1)*t] == 1/2 (r2[n*t] + r3[n*t] + (r2[n*t] - r3[n*t]) Cosh[
   2 (-1 + n) *t] + (-r1[n*t] + r4[n*t]) Sinh[2 t - 2 n* t]), r3[(n + 1)*t] == 1/2 (r2[n*t] + 
 r3[n*t] + (-r2[n*t] + r3[n*t]) Cosh[
   2 (-1 + n)* t] + (r1[n*t] - r4[n*t]) Sinh[2 t - 2 n *t]), r4[(n + 1)*t] == 1/2 (r1[n*t] + r4[n*t] + (-r1[n*t] + r4[n*t]) Cosh[2 (-1 + n) *t] + (r2[n*t] - r3[n*t]) Sinh[2 t - 2 n *t]), r1[0] == 1, r2[0] == r3[0] == r4[0] == 0}, {r1[n], r2[n], r3[n], r4[n]}, n ]

Answer 1

One thing you got wrong is that you are missing a { in your equations. However, RSolve has limits and it can't solve the recurrences. You can try this alternative method. Use the following code:

ClearAll[r1, r2, r3, r4, t];
r1[0] = 1; r2[0] = r3[0] = r4[0] = 0;
r1[m_] := r1[m] = With[{n = m - 1}, FullSimplify[
1/2 (r1[n] + r4[n] + (r1[n] - r4[n]) Cosh[
    2 (-1 + n)*t] + (-r2[n] + r3[n]) Sinh[2 t - 2 n*t])]];
r2[m_] := r2[m] = With[{n = m - 1}, FullSimplify[
1/2 (r2[n] + r3[n] + (r2[n] - r3[n]) Cosh[
    2 (-1 + n)*t] + (-r1[n] + r4[n]) Sinh[2 t - 2 n*t])]];
r3[m_] := r3[m] = With[{n = m - 1}, FullSimplify[
1/2 (r2[n] + r3[n] + (-r2[n] + r3[n]) Cosh[
    2 (-1 + n)*t] + (r1[n] - r4[n]) Sinh[2 t - 2 n*t])]]; 
r4[m_] := r4[m] = With[{n = m - 1}, FullSimplify[
1/2 (r1[n] + r4[n] + (-r1[n] + r4[n]) Cosh[
    2 (-1 + n)*t] + (r2[n] - r3[n]) Sinh[2 t - 2 n*t])]];
Table[{n, r1[n], r2[n], r3[n], r4[n]}, {n, 0, 7}] // Column

You will notice the pattern of the output. The solution is this:

tt[n_] := t n (n - 3)/2;    
Table[{n, r1[n] == Cosh[tt[n]]^2, r2[n] == Sinh[2 tt[n]]/2, 
     r3[n] == -Sinh[2 tt[n]]/2, r4[n] == -Sinh[tt[n]]^2} // 
     Simplify, {n, 0, 11}] // Column

where all the equalities are True.