0
$\begingroup$

I am trying to find the values of L and \theta, but mathematica is unable to produce output. My code is given below, where the value of k is fixed, i.e., 0.75, but the value of B can be positive or negative.

Solve[{
   1/r^4 2 (r^2 + (L - B r^k + 
          B r^k Cos[\[Theta]])^2 Csc[\[Theta]]^2 - (-2 + r) (L - 
          B r^k + B r^k Cos[\[Theta]]) (L + B (-1 + k) r^k - 
          B (-1 + k) r^k Cos[\[Theta]]) Csc[\[Theta]]^2) == 0,
   -(1/(r^3))
     2 (-2 + r) (L - B r^k + 
        B r^k Cos[\[Theta]]) (B r^
         k + (L - B r^k) Cos[\[Theta]]) Csc[\[Theta]]^3 == 0},
  {L, \[Theta]}]

Can anyone please help me to solve these equations.

$\endgroup$
4
$\begingroup$

One approach is to introduce variables $x$ and $y$ in place of $\cos\theta$ and $\sin\theta$, like this

eq1 = 1/r^4 2 (r^2 + (L - B r^k + 
          B r^k Cos[θ])^2 Csc[θ]^2 - (-2 + r) (L - 
         B r^k + B r^k Cos[θ]) (L + B (-1 + k) r^k - 
         B (-1 + k) r^k Cos[θ]) Csc[θ]^2) == 0;

eq2 = -(1/(r^3)) 2 (-2 + r) (L - B r^k + 
      B r^k Cos[θ]) (B r^
        k + (L - B r^k) Cos[θ]) Csc[θ]^3 == 0;

eq3 = x^2 + y^2 == 1;

eqns = {eq1, eq2, eq3} /. Cos[θ] -> x /. Csc[θ] -> (1/y);

s = Solve[eqns, {L, x, y}] // Simplify;

Then use ArcTan[x,y] to recover solutions for $\theta$.

$\endgroup$
  • 2
    $\begingroup$ Another alternative would be to use the Weierstrass substitution θ -> 2 ArcTan[u]. $\endgroup$ – J. M. will be back soon Sep 16 at 12:53

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.