2
$\begingroup$

I have created the ListPlot shown below (from data in a multidimensional list), but it is not exactly what I aimed for. I aimed for everything shown, except I do not want any lines to border the shading.

How do I get rid of the lines?

My current code is:

ListPlot[{Part[mat, 1, 1, 6], Part[mat, 1, 2, 6], Part[mat, 1, 3, 6], Part[mat, 1, 4, 6], Part[mat, 1, 5, 6]}, Joined -> True, Filling -> Axis, PlotStyle -> {{blue , Thickness[0]}, {blue, Thickness[0]}, {blue, Thickness[0]}, {blue, Thickness[0]}, {blue, Thickness[0]}}]

enter image description here

Improve this question
$\endgroup$
1
  • 1
    $\begingroup$ You can use PlotStyle -> Transparent, FillingStyle -> Directive[Opacity@0.3, Blue] to get the filling without lines. $\endgroup$
    – Lukas Lang
    Sep 10 '19 at 10:12
1
$\begingroup$ 
SeedRandom[1]
data = Accumulate @ RandomReal[10, {5, 10}];

You can use the (undocumented) sub-option "LineOpacity" -> 0 for PlotStyle:

ListLinePlot[data, 
 Filling -> Axis, 
 PlotStyle -> Directive[Blue, "LineOpacity" -> 0]]

enter image description here

ListLinePlot[data, 
 Filling -> Prepend[1 -> Axis][# -> {#2} & @@@ Partition[Reverse@Range[5], 2, 1]], 
 PlotStyle -> Directive["LineOpacity" -> 0], 
 PlotLegends -> SwatchLegend[Automatic, Range[5]]]

enter image description here

Alternatively, a slight variation on Lukas's suggestion in the comments:

ListLinePlot[data,
  Filling -> Axis, 
  PlotStyle -> None, 
  FillingStyle -> Opacity[0.2, Blue]]

enter image description here

Improve this answer
$\endgroup$
1
  • 1
    $\begingroup$ It's also possible to use the multi-argument form to Filling to override an Opacity[0] in the standard PlotStyle. $\endgroup$
    – b3m2a1
    Sep 11 '19 at 2:49

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.