4
$\begingroup$

I want to keep the same GeoZoomLevel, but increase the resolution of the labels. I'm struggling to control that:

GeoGraphics[{Green, Polygon@Entity["Country", "Greenland"]}, 
 GeoRange -> "World", GeoProjection -> "Equirectangular", 
 GeoZoomLevel -> 1, ImageSize -> 1100, GeoResolution -> 4, 
 RasterSize -> 900]

enter image description here

$\endgroup$
6
$\begingroup$

Use background without labels (with the option GeoBackground -> GeoStyling["StreetMapNoLabels"]) and add the labels as Text primitives:

oceanlabels = Text[Style[StringRiffle[StringSplit[ToUpperCase@#["Name"]], "\n"], 
      24, Gray, Italic, ShowStringCharacters -> False], 
     GeoGridPosition[GeoPosition[#["CenterCoordinates"]], "Equirectangular"]] & /@ 
  (Entity["Ocean", #] & /@ {"PacificOcean", "AtlanticOcean", "IndianOcean"});

continentlabels = Text[Style[StringRiffle[StringSplit[ToUpperCase@#["Name"]], "\n"], 
      24, Gray, Bold, ShowStringCharacters -> False], 
     GeoGridPosition[GeoPosition[#["CenterCoordinates"]], "Equirectangular"]] & /@ 
   Most[EntityList["GeographicRegion"]];

GeoGraphics[{Green, Polygon@Entity["Country", "Greenland"], oceanlabels, continentlabels}, 
 GeoRange -> "World", GeoProjection -> "Equirectangular", 
 GeoZoomLevel -> 1, ImageSize -> 1100,
 GeoBackground -> GeoStyling["StreetMapNoLabels"]]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.