0
$\begingroup$

I am a selflearner and really new to mathematica software and I am struggling to solve the following system of equations...:

$(x-d)(y-d)+3(x+1)(1-y)=0$

$(x-d)^2+3(x+1)^2=(y-d)^2+3(1-y)^2$

$(z-x)(y-d)+(w-x\sqrt3-\sqrt3)(-y\sqrt3+\sqrt3)=0$

$(y-d)\frac{(1+x)\sqrt3+w}{2}+\sqrt3(y-1)\frac{x+z-2d}{2}=0$

$\vert{x}\vert,\vert{y}\vert, \vert{z}\vert, \vert{d}\vert<1,0<w<\sqrt3$

The $x, y,z, w$ are the unknown quantities and $d$ a parameter (all real). Probably there is only one solution iff $d$ is restricted to a smaller interval than it is defined...

Every time I write the code in the notebook I get the message "WolframAlpha cannot understand what you want to do". Could someone help me please?

What I write in the notebook is:

Reduce[{(x-d)(y-d)+3(x+1)(1-y)==0, (x-d)^2+3(x+1)^2==(y-d)^2+3(1-y)^2, (z-x)(y-d)+(w-xsqrt3-sqrt3)(-ysqrt3+sqrt3)==0, (y-d)(1/2)((x+1)sqrt3+w)+(y-1)sqrt3(1/2)(x+z-2d)==0, -1

$\endgroup$
2
  • 2
    $\begingroup$ Can you include the code that you tried? $\endgroup$
    – MelaGo
    Commented Sep 6, 2019 at 19:59
  • $\begingroup$ @MelaGo, I edited my question as you consulted me and sorry for the late response but I had to do some things in real life here ): $\endgroup$
    – dmtri
    Commented Sep 7, 2019 at 11:03

1 Answer 1

6
$\begingroup$
Clear["Global`*"]

eqns = And @@ {(x - d) (y - d) + 3 (x + 1) (1 - y) == 0,
    (x - d)^2 + 3 (x + 1)^2 == (y - d)^2 + 3 (1 - y)^2,
    (z - x) (y - d) + (w - x Sqrt[3] - Sqrt[3]) (-y Sqrt[3] + Sqrt[3]) == 0,
    (y - d) ((1 + x) Sqrt[3] + w)/2 + Sqrt[3] (y - 1) (x + z - 2 d)/2 == 0,
    -1 < x < 1, -1 < y < 1, -1 < z < 1,
    0 < w < Sqrt[3], -1 < d < 1};

The equations as you expressed them have no solution

Solve[eqns, {x, y, z, w}, Reals]

{}

Relaxing the constraint on z, w, and d to merely that they are real

solR = Solve[eqns[[1;;6]], {x, y, z, w}, Reals];

There is a single solution

Length@solR

(* 1 *)

The variables are each expressed as a ConditionalExpression with a common condition

cond = solR[[1, All, -1, -1]] // Union

(* {-2 + Sqrt[3] < d < 2 - Sqrt[3]} *)

which is approximately

cond[[1]] // N

(* -0.267949 < d < 0.267949 *)

Using this constraint

sol = solR[[1]] // FullSimplify[#, cond] &

(* {x -> 1/2 (-3 + Sqrt[3] - (1 + Sqrt[3]) d), 
  y -> 1/2 (3 - d - Sqrt[3] (1 + d)), z -> 1/2 (3 + Sqrt[3] (-1 + d) + 5 d), 
  w -> 1/2 (-3 + Sqrt[3] + (3 + Sqrt[3]) d)} *)

Verifying,

eqns[[1 ;; 6]] /. sol // Simplify[#, cond] &

(* True *)

The intervals for {x, y, z, w} are

({x, y, z, w} /. sol // Simplify) /.
  d -> Interval[{-2 + Sqrt[3], 2 - Sqrt[3]}] // Simplify

(* {Interval[{-1, -2 + Sqrt[3]}], Interval[{2 - Sqrt[3], 1}], 
 Interval[{-2 + Sqrt[3], 5 - 2 Sqrt[3]}], Interval[{-3 + Sqrt[3], 0}]} *)

or approximately,

% // N // Chop

(* {Interval[{-1., -0.267949}], Interval[{0.267949, 1.}], 
 Interval[{-0.267949, 1.5359}], Interval[{-1.26795, 0}]} *)
$\endgroup$
1
  • $\begingroup$ Thanks a lot for your answer, I did a mistake in one of the equations I wrote in my questions but I understood the way you solved it so I will do it myself now, +25 $\endgroup$
    – dmtri
    Commented Sep 7, 2019 at 17:12

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.