Problem with complex eigenvalues in periodic Sturm-Liouville problem

Question

I'm having trouble using NDEigenvalues to obtain the first few eigenvalues for a differential operator on the circle of radius one-half.

$\qquad Lf(x) = f''(x)+ (-1-\sin(2x))f'(x)$

Considering this on the space $[0,\,\pi]/\sim$, this is a periodic Sturm-Liouville problem. It can be easily made self adjoint and, thus, should have a real spectrum. However, no matter how I play with the model, I still get complex eigenvalues.

NDEigenvalues[{f''[x] - (1 + Sin[2 x])f'[x], f[0] == f[Pi]}, f[x], {x, 0, Pi}, 10]

{0. +0. I, -4.16187 + 1.97304 I, -4.16187 - 1.97304 I, -16.1379 + 3.99737 I, -16.1379 - 3.99737 I, -36.1651 - 5.99943 I, -36.1651 + 5.99943 I, -64.3269 -7.99966 I, -64.3269 + 7.99966 I, -100.866 - 9.99757 I}

What am I doing wrong? Does this differential operator with these boundary conditions in fact not have real eigenvalues or am I using the function incorrectly?

Please advise!

Answer 1

We can show that the eigenvalue problem is not self-adjoint by finding 2 comparison functions which satisfy the boundary condition but do not satisfy the equation $$\int_0^\pi f \,L(g) \,dx \,\,=\, \int_0^\pi g \,L(f) \,dx \,\,.$$

First we define the operator and calculate a few eigenvalues like this

L[f_, x_] := (  D[f[z], z, z] - (1 + Sin[2 z])  D[f[z], z]  ) /. z :> x

NDEigenvalues[{L[g, x], g[0] == g[Pi]}, g[x], {x, 0, Pi}, 5]

/*  {0. + 0. I,  -4.16187 - 1.97304 I, -4.16187 + 1.97304 I, 
                -16.1379  + 3.99737 I, -16.1379 - 3.99737 I}  */

The above shows the definition of $L$ produces the same results as the original expression.

Next we choose 2 comparison functions, $f$ and $g$, that satisfy $f(0)=f(\pi)$ and $g(0)=g(\pi)$

f[z_] := z (z - π)
g[z_] := z f[z]

Now we evaluate the integrals

Integrate[ g[x] L[f, x], {x, 0, π}]
Integrate[ f[x] L[g, x], {x, 0, π}]

/*   1/60  π^2 (-45 - 10 π^2 + π^3)
   -(1/60) π^2 ( 45 + 10 π^2 + π^3)  */

Since the 2 integrals differ, the eigenvalue problem with the given operator and boundary condition is not self-adjoint.