Help me with understanding root objects [duplicate]

I solved an polynomial equation of degree 20 and got root objects as solutions. I cannot understand how to match such output to any standard analytic form. After studying Function and Root, I still can't understand how use the solutions, so please can anyone help me to understand the results I am getting?

First[Solve[(x + 1)^20 + x - 2 == 0, x]]


{x -> Root[-1 + 21 #1 + 190 #1^2 + 1140 #1^3 + 4845 #1^4 + 15504 #1^5 + 38760 #1^6 + 77520 #1^7 + 125970 #1^8 + 167960 #1^9 + 184756 #1^10 + 167960 #1^11 + 125970 #1^12 + 77520 #1^13 + 38760 #1^14 + 15504 #1^15 + 4845 #1^16 + 1140 #1^17 + 190 #1^18 + 20 #1^19 + #1^20 &, 1]}

I need the total meaning of such output to apply it in real calculations

eqn = (x + 1)^20 + x - 2 == 0;

(sol = First@Solve[eqn, x]) // InputForm

(* {x -> Root[-1 + 21*#1 + 190*#1^2 +
1140*#1^3 + 4845*#1^4 +
15504*#1^5 + 38760*#1^6 +
77520*#1^7 + 125970*#1^8 +
167960*#1^9 + 184756*#1^10 +
167960*#1^11 + 125970*#1^12 +
77520*#1^13 + 38760*#1^14 +
15504*#1^15 + 4845*#1^16 +
1140*#1^17 + 190*#1^18 +
20*#1^19 + #1^20 & , 1, 0]} *)


The exact solutions of the equation are Root objects. Because the polynomial is of high order, the roots cannot be expressed in terms of radicals. Root objects can be used the same as any solution. For example, to verify that the solution satisfies the original equation:

eqn /. sol // Simplify

(* True *)


Use N to get the approximate numeric value of a Root object

sol // N // InputForm

(* {x -> -2.0727396474052435} *)


For a much smaller order polynomial the Root objects can be converted to radicals.

eqn2 = (x + 1)^3 + x - 2 == 0;

(sol2 = First@Solve[eqn2, x]) // InputForm

(* {x -> Root[-1 + 4*#1 + 3*#1^2 + #1^3 & , 1, 0]} *)


Verifying,

eqn2 /. sol2 // Simplify

(* True *)


sol2r = sol2 // ToRadicals

(* {x -> -1 - (2/(3 (27 + Sqrt[741])))^(1/3) +
(1/2 (27 + Sqrt[741]))^(1/3)/3^(2/3)} *)


Verifying,

eqn2 /. sol2r // Simplify

(* True *)


The numeric value is

sol2 // N

{x -> 0.213412}

• Thanks @Bob Hanlon for explaining this Aug 29, 2019 at 3:46