0
$\begingroup$

I have to find all the maxima of the function

fun[t_?NumberQ] := NIntegrate[1/y^(11/3) Cos[y t], {y, 1, 2 }]

To find the poit with zero first derivative I have done:

Reduce[1/y^(11/3) Cos[y t] == 0, t]

with result:

C[1] \[Element] Integers &&  y != 0 && (t == (-(\[Pi]/2) + 2 \[Pi] C[1])/y ||  t == (\[Pi]/2 + 2 \[Pi] C[1])/y) 

Now how do I find which of these points are the maxima? I tought to use the second derivative of fun[t], which is the first derivative of the function inside the integral, but I don't know how to use the result of Reduce

$\endgroup$
  • 1
    $\begingroup$ I think fun'[t] is given by Integrate[D[1/y^(11/3) Cos[y t], t], {y, 1, 2}]. (You can also find the integral for fun symbolically as well, which might make finding the maxima easier.) $\endgroup$ – Michael E2 Aug 26 at 12:14
  • $\begingroup$ Have you tried NMaximize? It seems the global maximum is at t==0, with fun[0] == -(3/64) (-8 + 2^(1/3)) == 0.315941. You can use FindMaximum for the local maxima (e.g., there next maxima are at $\pm$ 4.976, etc.). $\endgroup$ – AccidentalFourierTransform Aug 26 at 13:02
2
$\begingroup$
Clear["Global`*"]

fun[t_] = Integrate[1/y^(11/3) Cos[y t], {y, 1, 2}] // Simplify

(* 1/2 (ExpIntegralE[11/3, -I t] + ExpIntegralE[11/3, I t]) - (
 ExpIntegralE[11/3, -2 I t] + ExpIntegralE[11/3, 2 I t])/(8 2^(2/3)) *)

Plot fun to obtain initial estimates for use with FindRoot

plt = Plot[fun[t], {t, -15, 15},
  WorkingPrecision -> 15]

enter image description here

sol = FindRoot[fun'[t] == 0, {t, #}, WorkingPrecision -> 15] & /@ 
  Range[-10, 10, 5]

(* {{t -> -11.0583535838776}, {t -> -4.97614346331708}, {t -> 0}, {t -> 
   4.97614346331708}, {t -> 11.0583535838776}} *)

Visually verifying:

Show[plt, Epilog -> {Red, AbsolutePointSize[4],
   Point[{t, fun[t]} /. sol]}]

enter image description here

$\endgroup$
0
$\begingroup$

The n-th maxima can be computed using

nthMax[n_Integer] := Quiet[
                      FindMaximum[
                       NIntegrate[1/y^(11/3) Cos[y t], {y, 1, 2}]
                      , {t, -8 + 2 π n}]
                     , {NIntegrate::inumr}]
nthMax /@ Range[5] // TeXForm

$$ \left( \begin{array}{cc} 0.315941 & \{t\to -\text{2.189*${}^{\wedge}$-16}\} \\ 0.148796 & \{t\to 4.97614\} \\ 0.0821207 & \{t\to 11.0584\} \\ 0.0553822 & \{t\to 17.269\} \\ 0.0415163 & \{t\to 23.5158\} \\ \end{array} \right) $$

If you want an analytic formula for large $n$, you can use $$ -2 \tan ^{-1}\left(\sqrt{\frac{\sqrt{64+8\ 2^{2/3}}+3 \sqrt[3]{2}}{8+\sqrt[3]{2}}}\right)+2 \pi n+\frac{1+\frac{6}{\sqrt{4+\frac{1}{\sqrt[3]{2}}}}}{(3 \pi ) n}+\mathcal O(1/n^2) $$

Here is the numeric result minus the asyptotic expansion, keeping the $\mathcal O(n),\mathcal O(1)$, and $\mathcal O(1/n)$ approximations, respectively:

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.