3
$\begingroup$

enter image description here

The above is from Maple 2019.1. Is there a way to achieve the same result from MMA12?

Tried

Limit[Sum[Sqrt[1 + k^2/n^3] - 1, {k, 1, n}], {n -> Infinity}]

which did not work. Best I can get is a numerical approximation.

With[{n = 10^200}, NSum[Sqrt[1 + k^2/n^3] - 1, {k, 1, n}]]

0.166667

which is informative.

$\endgroup$
  • 1
    $\begingroup$ Can try this With[{n = 10^200}, NSum[Sqrt[1 + k^2/n^3] - 1, {k, 1, n}]] // Rationalize $\endgroup$ – PlatoManiac Aug 22 '19 at 1:02
  • $\begingroup$ @PlatoManiac Nice cheat :) $\endgroup$ – CasperYC Aug 22 '19 at 1:05
  • $\begingroup$ I totally agree ;) $\endgroup$ – PlatoManiac Aug 22 '19 at 1:11
  • 1
    $\begingroup$ With[{n = 10^220}, NSum[Sqrt[1 + k^2/n^3] - 1, {k, 1, n}]] yields -0.333333 in Mathematica 12.0. $\endgroup$ – mjw Aug 22 '19 at 1:27
  • 1
    $\begingroup$ @mjw - For v12 use With[{n = 10^220}, Block[{$MaxExtraPrecision = 700}, NSum[Sqrt[1 + k^2/n^3] - 1, {k, 1, n}, WorkingPrecision -> 15]]] // Rationalize $\endgroup$ – Bob Hanlon Aug 22 '19 at 4:09
3
$\begingroup$

Some trickery: introduce a regulator to improve the convergence, which allows you to expand in $1/n$, and finally take the limit explicitly:

Series[(Sqrt[1 + k^2/n^3] - 1) E^(-ϵ k), {n, ∞, 6}]

$$ \left(\sqrt{\frac{k^2}{n^3}+1}-1\right) e^{-\epsilon k}=e^{-\epsilon k}\left(\frac{k^2}{2 n^3}-\frac{k^4 }{8 n^6}+\mathcal O(n^{-7})\right) $$

Sum[(E^(-k ϵ) k^2)/(2 n^3) - (E^(-k ϵ) k^4)/(8 n^6), {k, 1, n}]
Limit[%, ϵ -> 0]

$$ \sum_{k=1}^n\left(\sqrt{\frac{k^2}{n^3}+1}-1\right) e^{-\epsilon k}=\frac{40 n^5+54 n^4+5 n^3-10 n^2+1}{240 n^5}+\mathcal O(\epsilon) $$

Limit[%, n -> ∞]

$$ \color{red}{\frac{1}{6}} $$

|improve this answer|||||
$\endgroup$
2
$\begingroup$

It's a shame that AsymptoticSum doesn't work out of the box for this problem. We can help it along by expanding the expression around $n=\infty$ and then using AsymptoticSum. Here is the expansion:

coeff = SeriesCoefficient[Sqrt[1 + k^2/n^3] - 1, {n, Infinity, m}];
coeff //TeXForm

$\begin{cases} \binom{\frac{1}{2}}{\frac{m}{3}} k^{2 m/3} & (m \bmod 3)=0\land m>0 \\ 0 & \text{True} \end{cases}$

The only nonzero terms are when $m$ is a positive multiple of 3. Let's check by resumming the individual terms:

Sum[k^(2 m)/n^(3 m) Binomial[1/2, m], {m, Infinity}]

-1 + Sqrt[(k^2 + n^3)/n^3]

Next, let's sum up the general coefficient using AsymptoticSum to leading order:

terms[m_] = Assuming[
    m ∈ Integers && m > 0,
    Apart[
        FullSimplify @ AsymptoticSum[k^(2 m)/n^(3 m) Binomial[1/2, m], {k, 1, n}, {n, Infinity, 1}],
        n
    ]
];
terms[m] //TeXForm

$\frac{\binom{\frac{1}{2}}{m} n^{1-m}}{2 m+1}+\frac{1}{2} \binom{\frac{1}{2}}{m} n^{-m}$

Clearly, the leading term is order $n^{1-m}$ and comes from the first coefficient:

terms[1]

1/6 + 1/(4 n)

The $1/n$ dependence is incomplete as we need to include the $m=2$ coefficient as well.

terms[2]

-1/(16 n^2) - 1/(40 n)

To get the $n$ series to a particular order, we can series expand the expression, and then use AsymptoticSum on the series expansion to the right order:

expansion[order_] := 
    AsymptoticSum[
        Normal @ Series[Sqrt[1 + k^2/n^3] - 1, {n, Infinity, order}],
        {k, 1, n},
        {n, Infinity, Max[Floor[order/3] - 1, 1]}
    ]

For example:

expansion[20] //TeXForm

$-\frac{651}{66560 n^5}+\frac{5}{352 n^4}-\frac{17}{1152 n^3}+\frac{5}{168 n^2}+\frac{9}{40 n}+\frac{1}{6}$

|improve this answer|||||
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.