I am currently solving a 2D convection-conduction equation. The convection is only working on the x direction. The governing equation and its associated conditions are given as

enter image description here

where T is the temperature, x and z are the spatial distances, t is the time, and v is the velocity.

Firstly, I applied the Laplace transform method to eliminate t. These equations then become

enter image description here

where T with a bar represents the function in the Laplace domain and s denotes the Laplace parameter.

Later, I used the function called FourierTransform in MMA12 to transform the aforementioned equations to the Laplace-Fourier domain. The results are obtained as

enter image description here

in which T with the double bars represents the function in the Laplace-Fourier domain, a is the Fourier parameter, i is the imaginary unit, and 𝛿 is the dirac delta function.

After applying the DSolve function, I got this result

enter image description here

It can be observed that the convection term is disappeared (i.e., v = 0). Am I missing something here? Or is the convection term not important in this PDE? Thank you for the help.

The associated code I used to obtain the function in Fourier domain is

FourierTransform[T''[x], x, a]


-a^2 FourierTransform[T[x], x, a]

The convection term with applying Fourier transform

FourierTransform[-v*T'[x], x, a]


I a v FourierTransform[T[x], x, a]


FourierTransform[1/s, x, a]


(Sqrt[2 \[Pi]] DiracDelta[a])/s

Applying the DSolve

DSolve[{s*T[z] == -a^2*T[z] + I a v*T[z] + T''[z], 
   T[0] == (Sqrt[2 \[Pi]] DiracDelta[a])/s, T[1] == 0}, {T[z]}, 
  z] // Simplify

one gives

T[z] -> (E^(-Sqrt[s] z) (E^(2 Sqrt[s]) - E^(2 Sqrt[s] z)) Sqrt[
  2 \[Pi]] DiracDelta[a])/((-1 + E^(2 Sqrt[s])) s)
  • $\begingroup$ Can you show your code to obtain these? LaTeX is good, but if we can see the code you used it is really helpful in helping us help you :) which is the convection term originally also? If it is time dependent that may be your answer, as you eliminated t—but if it is a result of DSolve, then one could surmise that it disappeared due to it being dx/dt? I’m not as learned on this as I should be, admittedly. $\endgroup$ Aug 21, 2019 at 3:43
  • 1
    $\begingroup$ @CATrevillian hi, I added the code I used to obtain the result of the ODE in the Laplace domain. The convection term is the function multiplied by v. It seems that the use of the Laplace transform does not lead to such a result. The disappearance of v is confusing me. $\endgroup$
    – LingLong
    Aug 21, 2019 at 3:56
  • $\begingroup$ s is signal yeah? Is that not like the velocity? But also what about your T[0] not having the other terms in it? $\endgroup$ Aug 21, 2019 at 4:06
  • $\begingroup$ @CATrevillian Actually, s in the model is a Laplace parameter which can be found after applying the Laplace transform. Also, the convection term is -v dT/dx in the equation. T[0]=0 means the temperature in the investigated domain is zero initially. $\endgroup$
    – LingLong
    Aug 21, 2019 at 4:26
  • $\begingroup$ Thank you for the clarifications, in your final step, what you input into DSolve, the T(x=0) term does not include all of the items you list prior, could this be the cause? $\endgroup$ Aug 21, 2019 at 4:30

1 Answer 1


Let me extend my comment to an answer. I think the solution is correct. It's the boundary conditions at infinity that filter out influence of v. I'm not that familiar with the theory of integral transforms, but only functions that satisfy certain criterion can be FourierTransformed, which isn't satisfied by solution of PDE involving convective terms in many cases. Somewhat related:


To support my point from another side, let's solve the problem with a slightly different method. First write down the equation:

With[{T = T[t, x, z]}, eq = D[T, t] == D[T, x, x] - v D[T, x] + D[T, z, z];
 ic = T == 0 /. t -> 0;
 bc = {T == 1 /. z -> 0, T == 0 /. z -> 1}]

Then impose Laplace transform just as you've done:

{teq, tbc} = 
 LaplaceTransform[{eq, bc}, t, s] /. Rule @@ ic /. 
  HoldPattern@LaplaceTransform[a_, __] :> a

(* {s*T[t, x, z] == Derivative[0, 0, 2][T][t, x, z] - v*Derivative[0, 1, 0][T][t, x, z] + 
       Derivative[0, 2, 0][T][t, x, z], {T[t, x, 0] == 1/s, T[t, x, 1] == 0}} *)

I've made replacement HoldPattern@LaplaceTransform[a_, __] :> a because LaplaceTransform will cause trouble in subsequent programming. Just keep in mind T[t, x, z] in teq and tbc actually means Laplace transform of $T$.

Next, we use finite Fourier sine transform to eliminate derivative of z

tteq = finiteFourierSinTransform[teq, {z, 0, 1}, n] /. Rule @@@ tbc /. 
  HoldPattern@finiteFourierSinTransform[a_, __] :> a

s*T[t, x, z] == (-n)*Pi*(-(1/s) + n*Pi*T[t, x, z]) - v*Derivative[0, 1, 0][T][t, x, z] + 
     Derivative[0, 2, 0][T][t, x, z]

Similarly, I've made replacement HoldPattern@finiteFourierSinTransform[a_, __] :> a to avoid trouble in subsequent programming, keep in mind T[t, x, z] is actually finite Fourier sine transform of Laplace transform of $T$ in tteq.

Finally, directly solve tteq with DSolve:

DSolve[tteq, T[t, x, z], x][[1]]
{T[t, x, z] -> -((n π)/((-n^2 π^2 - s) s)) + 
   E^(1/2 (v - Sqrt[4 n^2 π^2 + 4 s + v^2]) x) C[1] + 
   E^(1/2 (v + Sqrt[4 n^2 π^2 + 4 s + v^2]) x) C[2]}

It's clear that C[…] can only be 0 if the boundary conditions at infinity are satisfied i.e. v doesn't play a role in the solution.

  • $\begingroup$ This is the result of incompatible boundary conditions and initial data. It is necessary to solve the problem using FEM and see what happens when the scale of the region increases along x. $\endgroup$ Aug 21, 2019 at 13:02
  • $\begingroup$ @Alex According to my (limited) experience, integral transform should be able to find the solution in the sense of limitation when b.c.s are inconsistent, here is an example: mathematica.stackexchange.com/q/127081/1871 $\endgroup$
    – xzczd
    Aug 21, 2019 at 14:11
  • $\begingroup$ After applying the Fourier sine transform to dT/dx, it will become the function in the Fourier cosine domain. Can we solve the ODE consisting of the function of T in the Fourier since and cosines domains simultaneously? $\endgroup$
    – LingLong
    Aug 27, 2019 at 7:46
  • $\begingroup$ @LingLong I'm not aware of such technique. Also, notice imposing Fourier sine transform is amount to implicitly setting b.c. at infinity i.e. the system will be over-determined if you use it in $t$ direction. $\endgroup$
    – xzczd
    Aug 27, 2019 at 8:30

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.