2
$\begingroup$

I need to solve symbolically an infinite system of coupled algebraic equations that I tried to do analytically but I could not. Solutions of these equations, $V_l^m$, define the coefficients of a some function $V$ (that I'm looking for) of the form

$$ V(r,\theta ,\varphi)=\sum _{l=0}^{\infty } \sum _{m=-l}^{+l} Y_l^m (\theta ,\varphi) V_l^m(r)=Y_0^0 V_0^0+Y_1^0 V_1^0+Y_1^1 V_1^1+Y_1^{-1} V_1^{-1}+\cdots $$

where $Y_l^m (\theta ,\varphi)$ denote the spherical harmonics.

These solutions $V_l^m$ obey the general form

$$ A\, V_l^m+\frac{B}{2}\left(-\sqrt{\frac{(l+m-1) (l+m)}{(2 l-1) (2 l+1)}} V_{l-1}^{m-1}+\sqrt{\frac{(l-m) (l-m-1)}{(2 l+1) (2 l-1)}} V_{l-1}^{m+1}+\sqrt{\frac{(l-m+1) (l-m+2)}{(2 l+1) (2 l+3)}} V_{l+1}^{m-1}-\sqrt{\frac{(l+m+2) (l+m+1)}{(2 l+1) (2 l+3)}} V_{l+1}^{m+1}\right)+m R V_l^m+\left(\delta _{l,1} \delta _{m,-1}-\delta _{l,1} \delta _{m,1}\right)D\, \lambda =0$$

which involves an infinite coupled equations.

Here $ A, B, D, R, \lambda$ are real constants.

In MA input form it gives

eq[l_,m_]:=A Subscript[V,{l,m}]+B/2 (Sqrt[((l-m+1)(l-m+2))/((2l+1)(2l+3))] Subscript[V,{l+1,m-1}]+Sqrt[((l-m)(l-m-1))/((2l+1)(2l-1))] Subscript[V,{l-1,m+1}]-Sqrt[((l+m-1)(l+m))/((2l-1)(2l+1))] Subscript[V,{l-1,m-1}]-Sqrt[((l+m+2)(l+m+1))/((2l+1)(2l+3))] Subscript[V,{l+1,m+1}])+(KroneckerDelta[l,1]KroneckerDelta[m,-1]-KroneckerDelta[l,1]KroneckerDelta[m,1])D \[Lambda]+m R Subscript[V,{l,m}]

Here just for the code I used $V_{\{l,m\}}$ instead of $V_l^m$.

For your information, solution of this problem is to express $V_{\{0,0\}}$ according to the variable $\lambda$ as

$$V_{\{0,0\}}=(f)\lambda$$

where $f$ is a term that includes all other solutions (maybe in the form of an infinite continued fraction).

Any help please on this problem! Can MA do something?

$\endgroup$
  • $\begingroup$ With eqs defined as the list of all equations explicitly given above, the number of distinct coefficients V is Length@Union@Cases[eqs, {_, _}, Infinity], which evaluates to 18, while the number of equations is Length@eqs, which evaluates to 10. Hence, the coefficients V in these equations are underdetermined. Of course, V in a larger set of equations might not be underdetermined, but it is impossible to say without knowing the general form of the equations. By the way use == instead of = in the equations to avoid syntax errors. $\endgroup$ – bbgodfrey Aug 19 at 17:28
  • $\begingroup$ @bbgodfrey, that is the problem for a coupled equations, so is there a possibility of having the solution if the general form is known? $\endgroup$ – Gallagher Aug 19 at 18:27
  • $\begingroup$ I just edited the question. $\endgroup$ – Gallagher Aug 19 at 19:40
2
$\begingroup$

first attempt

(apparently this isn't what the OP wanted)

I have edited the equation a bit because D is a reserved symbol and because subscripts are inconvenient:

eq[l_,m_] = d λ (KroneckerDelta[-1, m] KroneckerDelta[1, l] - KroneckerDelta[1, l] KroneckerDelta[1, m]) + a V[l, m] + 
            m R V[l, m] + 
            1/2 b (-Sqrt[(((-1 + l + m) (l + m))/((-1 + 2 l) (1 + 2 l)))] V[l-1, m-1] + 
                   Sqrt[((-1 + l - m) (l - m))/((-1 + 2 l) (1 + 2 l))] V[l-1, m+1] + 
                   Sqrt[((1 + l - m) (2 + l - m))/((1 + 2 l) (3 + 2 l))] V[l+1, m-1] - 
                   Sqrt[((1 + l + m) (2 + l + m))/((1 + 2 l) (3 + 2 l))] V[l+1, m+1]);

For every value of l, we have 2l+1 equations that can be used to determine {V[l+1,-l-1],...,V[l+1,l+1]}. There are 2l+3 unknowns, so we cannot determine all coefficients. Here I've chosen to solve for the {V[l+1,-l-1],...,V[l+1,l-1]} and leave V[l+1,l] and V[l+1,l+1] as free parameters:

S[l_] := First@Solve[Table[eq[l, m] == 0, {m, -l, l}], 
                     Table[V[l+1, m], {m, -l-1, l-1}]]

Try it out:

S[2]
(*    {V[3, -3] -> ..., 
       V[3, -2] -> ..., 
       V[3, -1] -> ..., 
       V[3, 0] -> ..., 
       V[3, 1] -> ...}    *)

We can stack these solutions in order to express the coefficients at a given value of l in terms of all smaller l-values:

Expand[S[2] /. S[1] /. S[0]]
(*    complicated expression for V[3,-3]...V[3,1] in terms of
      V[0, 0], V[1, 0], V[1, 1], V[2, 1], V[2, 2], V[3, 2], V[3, 3]}    *)

programmatically:

Clear[F];
F[l_] := Module[{f = S[l]},
  Do[f = f /. S[L], {L, l - 1, 0, -1}];
  Expand[f]]

Now calling F[2] gives the same result as the above Expand[S[2] /. S[1] /. S[0]].

second attempt

If you want to express $V_{0,0}$ in terms of $\{V_{L,-L},V_{L,-L+1},\ldots,V_{L,L}\}$ for a specific $L$, you can solve all the equations for $l<L$ for all the variables with $l<L$. For example, with $L=4$ we express $V_{0,0}$ in terms of $\{V_{4,-4},V_{4,-3},V_{4,-2},V_{4,-1},V_{4,0},V_{4,1},V_{4,2},V_{4,3},V_{4,4}\}$:

With[{L = 4},
  FullSimplify[V[0, 0] /. 
    First@Solve[
      Flatten[Table[eq[l, m] == 0, {l, 0, L - 1}, {m, -l, l}]], 
      Flatten[Table[V[l, m],       {l, 0, L - 1}, {m, -l, l}]]]]]

-((b (-10290 Sqrt[7] a^7 d λ + 42 Sqrt[15] a^2 b^3 R (35 Sqrt[7] R^2 (-V[4, -2] + V[4, 2]) + 2 b^2 (7 V[4, -4] - Sqrt[7] V[4, -2] + Sqrt[7] V[4, 2] - 7 V[4, 4])) - 294 Sqrt[15] a^4 b^3 R (7 V[4, -4] - Sqrt[7] V[4, -2] + Sqrt[7] V[4, 2] - 7 V[4, 4]) + 6 Sqrt[15] b^3 R (21 Sqrt[7] b^2 R^2 (V[4, -2] - V[4, 2]) + 49 R^4 (7 V[4, -4] + 4 Sqrt[7] V[4, -2] - 4 Sqrt[7] V[4, 2] - 7 V[4, 4]) + b^4 (-7 V[4, -4] + Sqrt[7] V[4, -2] - Sqrt[7] V[4, 2] + 7 V[4, 4])) + 49 a^5 (174 Sqrt[7] b^2 d λ + 2940 Sqrt[7] d R^2 λ + b^3 (-7 Sqrt[15] V[4, -4] + 2 Sqrt[105] V[4, -2] - 3 Sqrt[42] V[4, 0] + 2 Sqrt[105] V[4, 2] - 7 Sqrt[15] V[4, 4])) - 14 a^3 (153 Sqrt[7] b^4 d λ + 1680 Sqrt[7] b^2 d R^2 λ + 36015 Sqrt[7] d R^4 λ + 35 Sqrt[3] b^3 R^2 (7 Sqrt[5] V[4, -4] + Sqrt[35] V[4, -2] - 3 Sqrt[14] V[4, 0] + Sqrt[35] V[4, 2] + 7 Sqrt[5] V[4, 4]) - 2 b^5 (7 Sqrt[15] V[4, -4] - 2 Sqrt[105] V[4, -2] + 3 Sqrt[42] V[4, 0] - 2 Sqrt[105] V[4, 2] + 7 Sqrt[15] V[4, 4])) + a (162 Sqrt[7] b^6 d λ + 252 Sqrt[7] b^4 d R^2 λ + 50274 Sqrt[7] b^2 d R^4 λ + 370440 Sqrt[7] d R^6 λ + 14 Sqrt[3] b^5 R^2 (28 Sqrt[5] V[4, -4] + Sqrt[35] V[4, -2] - 6 Sqrt[14] V[4, 0] + Sqrt[35] V[4, 2] + 28 Sqrt[5] V[4, 4]) + 49 Sqrt[3] b^3 R^4 (77 Sqrt[5] V[4, -4] + 8 Sqrt[35] V[4, -2] - 27 Sqrt[14] V[4, 0] + 8 Sqrt[35] V[4, 2] + 77 Sqrt[5] V[4, 4]) - 3 b^7 (7 Sqrt[15] V[4, -4] - 2 Sqrt[105] V[4, -2] + 3 Sqrt[42] V[4, 0] - 2 Sqrt[105] V[4, 2] + 7 Sqrt[15] V[4, 4]))))/(3 Sqrt[ 42] (1715 a^9 - 1225 a^7 (2 b^2 + 21 R^2) + 7 a^5 (156 b^4 + 2380 b^2 R^2 + 15435 R^4) - a^3 (174 b^6 + 3045 b^4 R^2 + 31850 b^2 R^4 + 145775 R^6) + 3 a (3 b^8 + 58 b^6 R^2 + 651 b^4 R^4 + 5880 b^2 R^6 + 20580 R^8))))

You can do this for larger values of $L$, but it gets more difficult.

$\endgroup$
  • $\begingroup$ Roman, thank's for this approach, but the idea is not to calculate all solutions, it's impossible, so I try to express only V[0,0] according to the others solutions. I know that MA can do it. $\endgroup$ – Gallagher Aug 19 at 21:44
  • 1
    $\begingroup$ If you know that Mathematica can do it, then why don't you tell us? Why are you asking? $\endgroup$ – Roman Aug 19 at 21:50
  • $\begingroup$ Sorry Roman, I'm new with Mathematica, I think that Mathematica is very powerful. $\endgroup$ – Gallagher Aug 19 at 21:54
  • $\begingroup$ I think that it's possible to proceed by truncation at different coefficient by dropping the higher order coefficients in order to build a symbolic solution of the form V[0,0] = f(V[l+1,m+1],...) = f(f(V[l,m],...)) = f(f(f(V[l-1,m-1],...))) = f(f(.......f(V[1,1]))) \lambda, so how do it with Mathematica? $\endgroup$ – Gallagher Aug 20 at 14:01
  • $\begingroup$ Apparently it's impossible to compute the function $V(r,\theta,\varphi)$? $\endgroup$ – Gallagher Aug 20 at 16:56

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.