Extract outputs from a WHILE loop in a table format

Question

How can I convert my multiple outputs of a while loop in a table form and save it for later use. Here is a sample code:

i = 1;
While[i < 6, c = 2^i; d = 3^i; Print[c "           ", d]; i++]

The actual output should look like this:

Eventually, my goal is to eliminate certain rows based on a specific condition that values in column 2 satisfy.

(Here, my while loop is essential in what I am doing in my actual code. So assuming that cannot be changed is there a way to convert the output in table format? I apologize for any confusion)

Answer 1

Use Table instead of a While loop:

table = Table[{2, 3}^i, {i, 5}]

{{2, 3}, {4, 9}, {8, 27}, {16, 81}, {32, 243}}

Or

table = Transpose[Table[i^Range[5], {i, 2, 3}]]

{{2, 3}, {4, 9}, {8, 27}, {16, 81}, {32, 243}}

You can use Grid to display:

Grid[table, Dividers -> All] 

Update: If you have to use While you can AppendTo a list that is initialized to {}:

i = 1;
tab = {};
While[i < 6, AppendTo[tab, {2, 3}^i++]]
tab

{{2, 3}, {4, 9}, {8, 27}, {16, 81}, {32, 243}}

Alternatively, you can use Reap / Sow combination:

i = 1;
Reap[While[i < 6, Sow[ {2, 3}^i++]]][[2, 1]]

{{2, 3}, {4, 9}, {8, 27}, {16, 81}, {32, 243}}

Answer 2

It's not an issue for small lists such as provided in the example. However, AppendTo has issues for large ones.

With that in mind, an alternative approach is to assign your output list before entering the While[] block as in

i = 1;
out = Range[5];
While[i < 6,
 out[[i]] = {2, 3}^i; 
 i++
 ]
out

Format, using TableForm or Grid as you like.

But as @kglr suggests, his first Table[] example is more typical of Mathematica. While you can write Fortran (C, Pascal, ...) in any language, often there are better approaches.