2
$\begingroup$
ContourPlot3D[ f(x,y,z) ==0, {x,xmin,xmax},{y,ymin,ymax},{z,zmin,zmax},ContourStyle-> Thickness[2.0]]

Like in this case Thickness does not appear to Show:

b1 = ContourPlot3D [{.005 x^2 + .0055 y^2 + .0031 z^2 == 1}, {x, -20, 
   20}, {y, -20, 20}, {z, -15.5, 15.5}, ContourStyle -> Thickness[4]]

Also how can Contour Lines be shown in Tube Style? Thanks in advance for help.

$\endgroup$

marked as duplicate by Michael E2 plotting Aug 11 at 17:06

This question has been asked before and already has an answer. If those answers do not fully address your question, please ask a new question.

4
$\begingroup$
f[x_, y_, z_] := x^3 + y^2 - z^2 

You can use the (afaik undocumented) option "Extrusion":

ContourPlot3D[f[x,y,z] == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2},
   "Extrusion" ->. 2]

enter image description here

You can also use Extrusion -> .2 or Method ->{"Extrusion" -> .2}.

Alternatively, use PlotTheme -> "ThickSurface":

ContourPlot3D[f[x, y, z] == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2},
  PlotTheme -> "ThickSurface"]

enter image description here

To make the mesh lines into Tubes you can post-process:

ContourPlot3D[f[x, y, z] == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, 
  ContourStyle -> Opacity[.5, Orange], 
  MeshStyle -> Red] /. Line[x_] :> Tube[x, .03]

enter image description here

or use (also undocumented, afaik) option setting Tube[radius] for MeshStyle:

ContourPlot3D[f[x, y, z] == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, 
 ContourStyle -> Opacity[.5, Orange], MeshStyle -> Tube[.03]]

enter image description here

Note: The last two pictures are obtained using v9 (windows 10). Can't run the same code on v12 on free Wolfram Cloud because of cloud credit limits.

$\endgroup$
  • $\begingroup$ Thanks. It appears Extrusion-> .. works better. Next further on..in the given example how do we show with ContourPlot3D {x = xcon, y=ycn, z=zcon } Cartesian planes sections in Tube PlotStyle when so desired? $\endgroup$ – Narasimham Aug 11 at 14:46
  • $\begingroup$ @Narasimham, "further on..." part sounds like a good new question. $\endgroup$ – kglr Aug 11 at 15:38
  • $\begingroup$ OK I shall give a new question.. $\endgroup$ – Narasimham Aug 12 at 5:24

Not the answer you're looking for? Browse other questions tagged or ask your own question.