Mapping over the last level of a list, or equivalent operations

Question

I would like to style each element of my list using Style. But when I try

Lista = {{"a", "b", "a"}, {"n", "g", "r"}, {"d", "fgh", "Df"}}
Dimensions[Lista]
FormattedLista = Style[Lista, FontSize -> 10]
Dimensions[FormattedLista]

the structure of the original list is lost.

How can I map Style onto elements at the last level only, i.e. without changing the structure of the list?

Answer 1

Map[Style[#, FontSize -> 10] &, Lista, {2}]

The Style[#,FontSize->10]& is an anonymous function.

To see why this works, evaluate TreeForm[Lista]. The {2} as the third argument of Map means that the Style function will be inserted just above the second level of your expression and thus preserve the dimensions you desire.

Answer 2

How about a rule?

Lista = {{"a", "b", "a"}, {"n", "g", "r"}, {"d", "fgh", "Df"}};
formattedlist=Lista /. a_String -> Style[a, FontSize -> 10]

----EDIT----

and adding to your comment (and my confusion somewhat), if you want to apply styles to different heads (is that what you want?) you may amend your rules to something a little ugly:

Listb = {{"a", "b", "a", 12}, {"n", "g", "r", π}, {"d", "fgh", 
"Df", 0.2341}};
formattedlist = Listb /.{b___, a_Integer, c___} -> {b, Style[a, Red, 33], c}
                      /.{b___, a_Symbol, c___} -> {b, Style[a, Orange, 21], c} 
                      /.{b___, a_Real, c___} -> {b, Style[a, Brown, 9], c}
                      /.a_String -> Style[a, 11]

which gives

but I don't really understand if you want to apply Style to expressions so that they look different in your output stream or so that you use them as, say, a PlotLabel.

If this is a little confusing, it is worth noting that atoms (symbols, strings etc) with a specific Style stop being atoms:

LeafCount["a"]
(*Out*) 1

but

LeafCount[Style["a", 12]]
(*Out*) 3

which, can be misleading because, at the end of the day, all you are seeing is a string. In this case though, adding Style means that you can't "write" on a small, red thing, whether it is a string, symbol or whatever, i.e.

Style[a, Red, 12] = Interpolation[RandomReal[{0, 2}, 10]]

tells you a is tagged with the tag Style which is protected.

Answer 3

SetAttributes[style, Listable]
style[a_String] := Style[a, FontSize -> 10]

style has Listable attribute. It works on list, and keeps the shape.

Answer 4

Here's a way to apply formatting without changing the structure of the expression.

This is a bit unusual, and I do not recommend it as I am not absolutely sure it is reliable, but I thought it's worth showing:

fun = Function[str, "\!\(\*" <> ToString[ToBoxes@Style[str, Red], InputForm] <> "\)"]

list = {{"a", "b", "a"}, {"n", "g", "r"}, {"d", "fgh", "Df"}}
Map[fun, list, {-1}]

{Dimensions[list], Depth[list]}

(* ==> {{3,3}, 3} *)

Neither the depth nor the dimensions have changed because the formatting information has been embedded in the string.