Mathematica Stack Exchange is a question and answer site for users of Wolfram Mathematica. It only takes a minute to sign up.
Sign up to join this community
How can one derive programmatically a Cartesian equation when $x$ and $y$ are parametrically represented by trigonometric functions?
i.e.: Given that $x= \cos(2 t)$, and $y = -\sin(t)$, how can I find the Cartesian equation in terms of $x$, and also in terms of $y$?
{
x == Cos[2 t],
y == -Sin[t]
}
One can use GroebnerBasis[] with some assistance from TrigExpand[]:
GroebnerBasis[{x == Cos[2 t], y == -Sin[t]} // TrigExpand
// Append[Cos[t]^2 + Sin[t]^2 == 1], {x, y}, {Cos[t], Sin[t]}] // First
-1 + x + 2 y^2
Check:
% /. Thread[{x, y} -> {Cos[2 t], -Sin[t]}] // Simplify
0
GroebnerBasis[] to help me eliminate the terms with Cos[t] and Sin[t] (which is why they are in the third argument), and retain an expression only in terms of x and y. The "check" ensures that the original parametric equations give $0$ when substituted into the resulting implicit Cartesian equation previously (hence the %) produced by GroebnerBasis[].
$\endgroup$
Aug 6, 2019 at 3:30
If you need to go blindly, then have a look into the documentation of Eliminate, TrigExpandand Solve, and beware of the limitation of InverseFunction when solving into the form $y=f(x)$.
There are other better options (see answers by Ulrich Neumann and J.M) if you know where you are going.
Assuming[
-1 < x < 1,
Simplify@Eliminate[
{
x == Cos[2 t],
y == -Sin[t]
}
, t
]]
(* ArcCos[x] + 2 ArcSin[y] == 0 *)
Assuming[
0 < x < 1,
FullSimplify[
Solve[
ArcCos[x] + 2 ArcSin[y] == 0
, y
]]]
(* {{y -> -Sin[ArcCos[x]/2]}} *)
or
Eliminate[
TrigExpand@{
x == Cos[2 t],
y == -Sin[t]
}, t]
(* 2 y^2 == 1 - x *)
And then Solve.
Eliminate[] by performing a preliminary Weierstrass substitution: Eliminate[TrigExpand[{x == Cos[2 t], y == -Sin[t]} /. t -> 2 ArcTan[u]], u]
$\endgroup$
Aug 2, 2019 at 11:54
Eliminate handles transcendentals, even simple ones like this. I was probably a lot smarter when i got it to do that (way back in the last millennium).
$\endgroup$
Aug 2, 2019 at 16:08
The "Weierstrass substitution" gives a direct result
eq = { x == Cos[2 t], y == -Sin[t]} /. t -> 2 ArcTan[u] // TrigExpand
sol = Solve[eq, y, u]
(*{{y -> -(Sqrt[1 - x]/Sqrt[2])}, {y -> Sqrt[1 - x]/Sqrt[2]}}*)
Plot[y /. sol, {x, -1, 1}, Evaluated -> True]
u->Tan[t/2]<=> t->2 ArcTan[u] which transforms your trigonometric equations into rational equations in u, which might be solved easier. Additionally you restrict the solution to Pi <t<Pi
$\endgroup$
Aug 2, 2019 at 12:56
Sqrt and u=Tan[t/2] transforms one period -Pi<t<Pi to -Infinity<u<Infinity
$\endgroup$
Aug 4, 2019 at 12:35
{Sin[t], Cos[t], Tan[t]} /. t -> 2 ArcTan[u] // TrigExpand // Simplify
$\endgroup$
Aug 4, 2019 at 13:08
If you want to avoid inverse functions then you need to use trig identities to eliminate the parameter (if that is possible). For the example that you give,
x == Cos[2t] //TrigExpand
% /. Cos[t]^2 -> 1 - Sin[t]^2
% /. Sin[t] -> -y
(* x == 1 - 2 y^2 *)
so the curve is part of a parabola on its side,
ParametricPlot[Evaluate[{x, y} /. {x -> Cos[2 t], y -> -Sin[t]}], {t, 0, 10}]
More generally, one would have to proceed as in @rhermans answer.
Output result, /. is infix form of ReplaceAll, -> is infix form of Rule. To find out this sort of thing, highlight the %, /., or -> with the mouse and then press the F1 key to get the documentation.
$\endgroup$
Aug 3, 2019 at 1:46