Passing arguments into WolframScript in batch mode

Question

I am looking for a way to passing arguments into a WL script when WL run in batch modes. The test script is:

#!/usr/bin/env wolframscript

(*generate "num" samples of a mixed distribution*)
num = ToExpression[$ScriptCommandLine];
Print["num ", num];
Print /@ RandomVariate[
  MixtureDistribution[{1, 2}, {NormalDistribution[1, 0.2], 
    NormalDistribution[3, 0.1]}], num, WorkingPrecision -> 50]

The output file:

Mathematica 11.3.0 Kernel for Linux x86 (64-bit)
Copyright 1988-2018 Wolfram Research, Inc.
In[1]:= 
In[2]:= num {}

In[3]:= 
Out[3]= True


Out[4]= 1.2216923087229409686348818698669268506575506911553

And the sh script :

#!/bin/sh
#$ -cwd
/gpfs0/system/Mathematica/11.3/Executables/math < test.wls 3 > test_out.txt

It is looks that I do not succeed to pass the arguments to the script. Any suggestion on how to do it correctly?

Answer 1

Okay, so this is what your script might want to look like:

#!/usr/bin/env wolframscript

num = ToExpression[$ScriptCommandLine[[2]]];

Export[
    "~/Desktop/wstest/test"<>DateString[{"Hour", "Minute", "Second", "MillisecondShort"}]<>".txt"
    ,
    RandomVariate[
        MixtureDistribution[{1, 2},
            {NormalDistribution[1, Rationalize[.2]], NormalDistribution[3, Rationalize[.1]]}
        ]
        ,
        num
        ,
        WorkingPrecision -> 50
    ]
    ,
    "CSV"
]

And you can call it with

test.wls 3

from your shell (a chmod +x test.wls might be necessary). The result is a .txt file in the specified folder (with a timestamp added to make it unique) of the form

2.945267726074665622104002146319038844277342932419
3.0059934477355789443483766777766852723094126818552
2.9593531823056876773610286479120461237403695981006

Your major mistakes:

1) ToExpression[$ScriptCommandLine] needs a position specifier to actually grab the specific argument

2) you were trying to run this script in the math executable. That's not needed, it can just run as its own executable against wolframscript

3) I think you were overcomplicating things with the < and > redirection. With the information you've provided so far, that shouldn't be necessary.

Let me know if you have got further questions.