Check if a list consists of numbers

Question

I'd like to check if all elements of a list are numbers. I've tried

t = {5/4, 12}
MatrixQ[t, NumberQ]
MemberQ[t, NumberQ]
And @@ Table[NumberQ[t[[i]]], {i, 1, Length[t]}]

but only the last one yields the desired result. Is there a better way to check?

Answer 1

You can use Element:

Element[{$x_1 , x_2 , \ldots$}, dom] asserts that all the $x_i$ are elements of dom.

Using mgamer's example list:

{Pi, 0.4, 1, 2/2, 1./3} ∈ Reals

True

The built-in mathematical constants:

{Catalan, °, E, EulerGamma, Glaisher, GoldenRatio, Khinchin, MachinePrecision, π} ∈ Reals

True

{Pi, 1 + I, 1, .5} ∈ Reals

False

Answer 2

Given a list:

list = {Pi, 0.4, 1, 2/2, 1./3}

you can do:

And @@ (Head[#] === Real & /@ list)
(* False *)

Answer 3

Using MatchQ and NumericQ:

t = {5/4, 12, Pi, 0.4};

MatchQ[t, {__?NumericQ}]

(*True*)

Another way to do this, nice and shorter (Thanks to @Syed!):

AllTrue[NumericQ][t]

Answer 4

list = {EulerGamma, Pi, 0.4, 1, 2/2, 1./3};

Since V 13.3 we have RealValuedNumberQ and RealValuedNumericQ

AllTrue[list, RealValuedNumericQ]

True

AllTrue[list, RealValuedNumberQ]

False (* because of EulerGamma *)