Getting error General::munfl from NonlinearModelFit [duplicate]

Question

This question already has an answer here:

• New General::munfl error and loss of precision 2 answers
• How to check for underflow, and find a constant to correct it? 2 answers

I am trying to fit data to a sum of Gaussians.

This data is found in a file called lpeff.txt. So I write the following code:

model = 
  V1*Exp[-((r - μ1)^2/σ1^2)] + V2*Exp[-((r - μ2)^2/σ2^2)] + V3*Exp[-((r - μ3)^2/σ3^2)];

(* mydata = 
  Import[
    "C:\\Users\\em\\Documents\\lambda_we_threshold2\\vot\\lambda_p\\effective_lp\\lpeff.txt", 
    {"Data", All, {1, 2}}]; *)
mydata = Import["https://pastebin.com/raw/7m8XF3EN", "Table"];

myfit = 
  NonlinearModelFit[
    mydata, model, 
    {{V1, 53.55}, {μ1, 0.09466}, {σ1, -0.3954}, 
     {V2, 36480}, {μ2, -0.4239}, {σ2, 0.2253}, 
     {V3, -49.63}, {μ3, 0.3712}, {σ3, 0.1697}}, 
    r, 
    MaxIterations -> Infinity];

When I run the code, I get the following error:

General::munfl: 4.3598*10^-308/2 is too small to represent as a normalized machine number; precision may be lost

How can I fix this?

Answer 1

This might be an answer (but without your data or at least the range of values of your values for r I can't be certain).

Here is the plot of model predictions given the starting values used in NonlinearModelFit:

model = V1*Exp[-((r - μ1)^2/σ1^2)] + V2*Exp[-((r - μ2)^2/σ2^2)] + V3*Exp[-((r - μ3)^2/σ3^2)];
Plot[model /. {V1 -> 53.55, μ1 -> 0.09466, σ1 -> -0.3954, V2 -> 36480, μ2 -> -0.4239,
  σ2 -> 0.2253, V3 -> -49.63, μ3 -> 0.3712, σ3 -> 0.1697}, {r, -2, 1}, PlotRange -> All]

Given this result, you might get the error messages you show whenever values of r are less than -5 and greater than +5.

model /. {V1 -> 53.55, μ1 -> 0.09466, σ1 -> -0.3954, 
   V2 -> 36480, μ2 -> -0.4239, σ2 -> 0.2253, 
   V3 -> -49.63, μ3 -> 0.3712, σ3 -> 0.1697} /. r -> -5

model /. {V1 -> 53.55, μ1 -> 0.09466, σ1 -> -0.3954, 
   V2 -> 36480, μ2 -> -0.4239, σ2 -> 0.2253, 
   V3 -> -49.63, μ3 -> 0.3712, σ3 -> 0.1697} /. r -> 5

So to tell whether you just have very small numbers whose underflow needs fixing or you need better starting values depends on your data.

Answer 2

I get a different error (version difference?) but a good fit:

$Version
(*  "12.0.0 for Mac OS X x86 (64-bit) (April 7, 2019)"  *)

mydata = Import["https://pastebin.com/raw/7m8XF3EN", "Table"];

model = V1*Exp[-((r - μ1)^2/σ1^2)] + 
   V2*Exp[-((r - μ2)^2/σ2^2)] + 
   V3*Exp[-((r - μ3)^2/σ3^2)];

myfit = NonlinearModelFit[mydata, 
   model, {{V1, 53.55}, {μ1, 0.09466}, {σ1, -0.3954}, {V2, 
     36480}, {μ2, -0.4239}, {σ2, 
     0.2253}, {V3, -49.63}, {μ3, 0.3712}, {σ3, 0.1697}}, r,
    MaxIterations -> Infinity];

LinearAlgebra`BLAS`TRSV::oflow: Machine overflow encountered during computations.

Plot[myfit[r],
 {r, Min[data[[All, 1]]], Max[data[[All, 1]]]},
 Prolog -> {Red, Point@data}, PlotRange -> All]

The parameter values of V2 and μ2 seem extremely large and offsetting:

myfit["BestFitParameters"]
(*
  {V1 -> 40.168, μ1 -> 0.136379, σ1 -> -0.389159, 
   V2 -> 3.13376*10^162, μ2 -> -37.1206, σ2 -> 1.93767, 
   V3 -> -45.3854, μ3 -> 0.376968, σ3 -> 0.164943}
*)

It seems clear that the left-hand side of the data looks nothing like a normal distribution, which probably is the reason for the parameter values.