Converting list of string into integers and reshaping the original list

Question

I have the following list which I am importing from Python - thus the format:

l = {{"a", "[1,2,3,4,5]"}, {"b", "[6,7,8,9,10]"}}

I wonder how can I convert this to the following shape:

{{{"a"}, {1,2,3,4,5}}, {{"b"}, {6,7,8,9,10}}}

Essentially for each letter the numbers in front should be converted to integer and list so one can do operations on them.

Answer 1

One way:

Replace[l, s_String :> If[StringMatchQ[s, "[" ~~ ___ ~~ "]"],
   ToExpression["{" <> StringTake[s, {2, -2}] <> "}"], {s}], {2}]

Answer 2

l /. 
  s_String :> StringReplace[s, "[" ~~ st___ ~~ "]" :> ToExpression["{" <> st <> "}"]] /. 
  StringExpression -> Identity /. 
  s_String :> {s}

{{{"a"}, {1, 2, 3, 4, 5}}, {{"b"}, {6, 7, 8, 9, 10}}}

Also

l1 = l;
l1[[All, 1]] = Map[List]@l[[All, 1]];
l1[[All, 2]] = Map[ToExpression@StringJoin["List", #] &]@l[[All, 2]];
l1

{{{"a"}, {1, 2, 3, 4, 5}}, {{"b"}, {6, 7, 8, 9, 10}}}

l2 = StringReplace[#, {"[" -> "{", "]" -> "}"}] & /@ l;
l2[[All, 1]] = List /@ l2[[All, 1]];
l2[[All, 2]] = ToExpression[l2[[All, 2]]];
l2

{{{"a"}, {1, 2, 3, 4, 5}}, {{"b"}, {6, 7, 8, 9, 10}}}

l3 = MapAt[List, l, {All, 1}];
l3 = MapAt[ToExpression@StringReplace[#, {"[" -> "{", "]" -> "}"}] &, l3, {All, 2}];
l3

{{{"a"}, {1, 2, 3, 4, 5}}, {{"b"}, {6, 7, 8, 9, 10}}}

Answer 3

{{#1}, ToExpression@StringSplit[#2,"["|"]"|","]}&@@@l

alternatively, using regex:

{{#1}, ToExpression@StringSplit[#2,RegularExpression["\W{1}"]]}&@@@l

{{{a}, {1, 2, 3, 4, 5}}, {{b}, {6, 7, 8, 9, 10}}}