Find maximum according to a parameter

Question

I am new to Mathematica. I want to find the maximum of the functions:

FindMaximum[
 (1 + y)^2/((1 + y)^2 + (1 + x)^2)* 5 - y - (1/((1 + x)^2 + 1))*5 && 0 < y < 2 
, y]

So I want to find the maximum of above function, with y in the range 0 to 2, taking $x$ as a parameter. However it showed the error

FindMaximum::nrnum: 
The function value 1. +(5 (1+x)^2)/(1+(1+x)^2)-(5 (2. +x)^2)/(1+(2. +x)^2)
is not a real number at {y} = {1.}

How can I fix this?

It only works if I input a certain value for $x$ (such as x=1).

Thank you all so much!

Answer 1

Numerical solution using NMaximize

maxi[x_?NumericQ] :=NMaximize[{(1 + y)^2/((1 + y)^2 + (1 + x)^2)*5 -y - (1/((1 + x)^2 + 1))*5, 0 < y < 2}, y][[1]]

Plot[maxi [x], {x, -1, 3}] (* takes some time... *)

Answer 2

If you are looking for an analytical solution then use Maximize

ClearAll[expr, max, sol, x, y];
expr = (1 + y)^2/((1 + y)^2 + (1 + x)^2)*5 - y - (1/((1 + x)^2 + 1))*5;

max = Simplify[
   Maximize[
    {expr, 0 < y < 2}
    , y
    ]
   ];

The solution is not compact.

sol = Assuming[
   0 < y < 2,
   Simplify[expr /. Last@max]
   ];

Plot[
 sol
 , {x, -5, 5}
 , PlotTheme -> "Scientific"
 ]

---

If you are looking for a numerical minimization, then you got your syntax wrong and have to define all symbols either as values or minimizing variables.

FindMaximum[
{
 (1+y)^2/((1+y)^2+(1+x)^2)*5-y-(1/((1+x)^2+1))*5
 , 0<y<2
}, {x,y}]
(* {0.675445,{x->0.470469,y->1.16228}} *)

or

With[
{x=1},
FindMaximum[
 {
  (1+y)^2/((1+y)^2+(1+x)^2)*5-y-(1/((1+x)^2+1))*5
  , 0<y<2
 }
, {y}
]]
(* {0.550873,{y->1.41368}} *)

Answer 3

It is possible to do this numerically in cases where Maximize is unable to work symbolically. Here is your function:

expr = (1 + y)^2/((1 + y)^2 + (1 + x)^2)* 5 - y - (1/((1 + x)^2 + 1))*5 /. y -> y[x];
expr //TeXForm

$\frac{5 (y(x)+1)^2}{(y(x)+1)^2+(x+1)^2}-y(x)-\frac{5}{(x+1)^2+1}$

where I introduced an x dependence in the variable y. Then, the following NDSolveValue call finds an InterpolatingFunction result for the maximum function:

m = NDSolveValue[
    {
    D[D[expr, y[x]] == 0, x],
    z[x] == expr,
    y[0] == NArgMax[{expr /. x->0, 0 < y[0] < 2}, y[0]]
    },
    z,
    {x, 0, 2}
];

Visualization:

Plot[m[t], {t, 0, 2}]

Note that this approach can break down when different branches cross, or when boundary conditions (0 < y < 2) interfere.

Answer 4

Assuming[Element[x, Reals], 
  Maximize[{(1 + y)^2/((1 + y)^2 + (1 + x)^2)*5 - y - (1/((1 + x)^2 + 1))*5, 0 < y < 2}, y]]