Using `PlotLegends` with a `ColorFunction`

Question

Is there a way to put a legend mark with a color function rainbow?

For example:

legend2 = 
 Grid[{{Graphics[{Red, Thick, Line[{{0, 0}, {2, 0}}]}, 
     ImageSize -> 5], "u"}}]
u[x_] := x
Plot[u[x], {x, 0, 1}, ColorFunction -> "Rainbow", 
 PlotLegends -> Placed[legend2, {{1.05, 0.5}, {0, 0.5}}]]

In this case the plot marker is red. Is there a way to put a rainbow scale like the function?

Answer 1

u[x_] := x
sparkline = Plot[0, {x, 0, 1},
   ColorFunction -> (ColorData[ "Rainbow"][#] &), 
   PlotStyle -> Thick, 
   PlotTheme -> "Sparkline", Axes -> False];

Plot[u[x], {x, 0, 1}, 
  ColorFunction -> "Rainbow", 
  PlotStyle -> Thick, 
  PlotLegends -> Labeled[sparkline, "u", Right]]

An alternative ways is to use {sparkline} with the (undocumented) option "LegendItem" inside LineLegend:

Plot[u[x], {x, 0, 1}, 
 ColorFunction -> "Rainbow", 
  PlotStyle -> Thick, 
  PlotLegends -> LineLegend[Automatic, {u}, "LegendItem" -> {sparkline}]]

Variations on the same idea:

colorfunctions = {"Rainbow", "SolarColors"};
functions = {Sin[x], Cos[x]};

sparklines = MapThread[Plot[#, {x, 0, 2 Pi}, 
     ColorFunction -> #2, PlotStyle -> Thick, 
     PlotTheme -> "Sparkline", Axes -> False] &,
  {functions, colorfunctions}];

Show[MapThread[Plot[#, {x, 0, 2 Pi}, 
     ColorFunction -> #2, PlotStyle -> Thick, 
     PlotLegends -> LineLegend[Automatic, {TraditionalForm @ #}, 
        "LegendItem" -> {#3}, LegendMarkerSize -> Large]] &,
   {functions, colorfunctions, sparklines}]]

Update: In addition to "Line", "Curve" and "Doodle", we can use a number of built-in chart elements as the setting for "LegendItem":

Row[LineLegend[{Directive[Red, Dashed], Green, Blue, Orange}, 
   {"A", "B", "C", "D"},
    "LegendItem" -> #, LegendMarkerSize -> {30, 30}] & /@ 
   {"Line", "Curve", "Doodle", "Square", "GlassRectangle", "ArrowRectangle", 
   "Bubble", "NoiseBubble", "OscillatingBubble", 
   "SquareWaveBubble", {Graphics@ Disk[], 
    Graphics@Text@Style["*", 64], 
    Graphics@Text@Style["\[FreakedSmiley]", 36], 
    ExampleData[{"TestImage", "Mandrill"}]}}, 
  Spacer[10]]

Answer 2

You can use LegendLayout to modify the Line[] in LineLegend:

ClearAll[cfline];
cfline[cf_String] := cfline[ColorData@cf];
cfline[cf_][pairs_] := Grid[
   pairs /. 
    Line[{a_, b_}] :> 
     Line[Subdivide[a, b, 20], 
      VertexColors -> cf /@ Subdivide[0., 1., 20]]
   ];

Plot[u[x], {x, 0, 4},
 ColorFunction -> "Rainbow", 
 PlotLegends -> LineLegend["Expressions", LegendLayout -> cfline@"Rainbow"]]