# Finding intersections of circles with some parameter

I have a set of 5 points which depend on a parameter r, with 0 < r < 1, defining 3 circles and I want to show that the intersection points of the 2 circles lies inside the 3rd one.

My points are:

L2 = {0, r -383/48 - 16/3 r^(-2)}
L1 = {-2, r -95/24 - 8/3 r^(-2)}
U2 = {0, r + 1/6}
L3 = {0, r -3071/96 - 32/3 r^(-2)}
U1 = {0, r}


My 3 circles are:

CG = CircleThrough[{L1, L2, U2}]
CB = CircleThrough[{U1, L3, L1}]
CE = Circle[U1, 1/4]


I want to show that the upper intersection of CG with CB lies inside CE.

I am getting the equations of circles CG,CB (assume CGE and CBE) and solve them using

sGE = Solve[CGE == 0 && CEE == 0, {x, y}]


But then I am trying to compare the 2 solutions that get (in order to keep the upper one) but I am not even sure it is actually doing what I want this to do.

Apologies if it is "simple" but I have no experience in using Mathematica (or any similar software) and I am really struggling. Any help would be extremely appreciated!

Clear["Global*"]

L2 = {0, r - 383/48 - 16/3 r^(-2)};
L1 = {-2, r - 95/24 - 8/3 r^(-2)};
U2 = {0, r + 1/6};
L3 = {0, r - 3071/96 - 32/3 r^(-2)};
U1 = {0, r};
CG = CircleThrough[{L1, L2, U2}];
CB = CircleThrough[{U1, L3, L1}];
CE = Circle[U1, 1/4];


The equations of the circles are

CGE = Total[({x, y} - CG[[1]])^2] == CG[[2]]^2 // Simplify;

CBE = Total[({x, y} - CB[[1]])^2] == CB[[2]]^2 // Simplify;


The intersections are

intersections = {x, y} /.
Solve[{CGE, CBE, 0 < r < 1}, {x, y}, Reals] //
Simplify[#, 0 < r < 1] &;


Testing whether the intersections are within CE

Simplify[
RegionMember[CE /. Circle :> Disk, #] & /@ intersections,
0 < r < 1]

(* {False, False} *)


The circle CE is too small to enclose either of the intersection points

Manipulate[
Graphics[{
Lighter[Blue, 0.75], CG, CB,
Blue, CE,
Red, Point[intersections]},
Frame -> True,
PlotRange -> {{0, pr}, {-pr, pr}},
AspectRatio -> 2] /. r -> rr,
{{rr, 1, "r"}, 0.01, 1, 0.01,
Appearance -> "Labeled"},
{{pr, 10, PlotRange}, 10, 400, 10,
Appearance -> "Labeled"}]
`

• Thank you very much for the answer Bob. It is working perfectly and I am grateful for that! I had actually made a typo. U2 must be: U2 = {0, r + 1/16} And it is working! And a small mistake because r>4. (In practice I had set r=2^m, for m>2) I have another question (not of equal importance). If i wanted the x coordinate of L1, instead of being fixed at -2, to take any value -t, with t>0. How could I possibly do it and show that it always true? Thanks again! – ioannis Jul 4 at 12:02
• To ask an additional question, post a new question along with what you have attempted to include all of the code in copy and paste form. Identify where you are having problems. Also remember to upvote/accept answers that provide help. – Bob Hanlon Jul 4 at 12:31