Iterate over deepest values in a nested Association

Question

Is it possible to iterate over the values of the deepest layer of keys in a nested association? For example:

assoc = <| "a"->0, "b"-> <| "c"->"one" ,"d"->2 , "e"->3|>, "f"->4|>

Would it be possible to iterate over just the values of at the deepest level in this example {0,"one",2,3,4}? Or, possible to iterate over the deepest level of keys such that I could test the type for the value of each key?

Answer 1

Level[assoc, {-1}]
(*    {0, "one", 2, 3, 4}    *)

Answer 2

assoc /. Association -> (Values@*List) // Flatten

{0, "one", 2, 3, 4}

When some values are non-atomic this approach and the deepest Level approach give different results:

assoc2 = <| "a" -> foo[0],  "b" -> <| "c" -> "one" , "d" -> 2 , "e" -> 3|>, 
   "f" -> {bar[1], foo[3]}|>;

assoc2 /. Association -> (Values@*List) // Flatten

{foo[0], "one", 2, 3, bar[1], foo[3]}

Level[assoc2, {-1}]

{0, "one", 2, 3, 1, 3}

Answer 3

Map[
 AssociationMap[
  keyTest[#[[1]]] -> valueTest[#[[2]]] & 
  ],
 <|"a" -> 0, "b" -> <|"c" -> "one", "d" -> 2, "e" -> 3|>, "f" -> 4|>,
 {-2}
 ]

<|"a" -> 0, 
 "b" -> <|keyTest["c"] -> valueTest["one"], keyTest["d"] -> valueTest[2], 
   keyTest["e"] -> valueTest[3]|>, "f" -> 4|>