2
$\begingroup$

I am trying to evaluate

Integrate[x^2*Exp[I k (x - 1)], {k, -∞, ∞}, {x, -∞, ∞}]

Since $\frac{1}{2\pi}\int_{-\infty}^{\infty} e^{ik(x-1)} d{k}$ is $\delta(x-1)$, answer should be $\int_{-\infty}^{\infty} x^2[2\pi \delta(x-1)] dx =2\pi$.

However, Mathematica says that the integral does not converge.

$\endgroup$
  • $\begingroup$ Am I missing something? $\endgroup$ – Archisman Panigrahi Jun 26 at 10:53
  • 2
    $\begingroup$ The integral diverges. Probably better to use FourierTransform in such cases. $\endgroup$ – Daniel Lichtblau Jun 26 at 15:25
  • 1
    $\begingroup$ Integrate doesn't venture into generalized function territory for divergent integrals, so it won't yield an expression with DiracDelta in it. $\endgroup$ – John Doty Jun 26 at 19:39
  • $\begingroup$ The improper integral under consideration diverges. $\endgroup$ – user64494 Jun 27 at 5:31
4
$\begingroup$

It looks like OP is interested in seeing how the integral can be done without using a black box like FourierTransform function. As mentioned in the comments, when we do not think of this integral as a distribution, it behaves badly and seems to diverge. Therefore, it is useful to regularize the integral by introducing a small parameter ϵ which makes it convergent. For example

integral[k_] = Integrate[Exp[-ϵ k^2 + I k f], k]

enter image description here

where Erfi is the imaginary error function. The above result is an anti-derivative, which we can trivially verify to be correct by taking the derivative:

D[integral[k], k] // ExpandAll

enter image description here

We also can use that anti-derivative to evaluate the integral over -∞ < k < ∞:

Assuming[Element[{ϵ, f, k}, Reals] && ϵ > 0,
   result = Series[integral[k] - integral[-k], {k, ∞, 0}] // Normal
]

enter image description here

The Series expansion was not perfect since the exponential function is non-perturbative in powers of k; but it was good enough, since we can now see that all the terms still dependent on k go to zero for k -> ∞. So that actually

result = (E^(-(f^2/(4 ϵ))) Sqrt[π])/Sqrt[ϵ];

Of course, in Mathematica we can arrive at this directly without making reference to any anti-derivative

result = Integrate[Exp[-ϵ k^2 + I k f], {k, -∞, ∞}]

enter image description here

You might notice that this result is essentially a limit representation of the DiracDelta function:

enter image description here

However, it is not necessary for us to recognize this and substitute anything by hand. We can simply proceed with the second integration by specifying f = x-1 and multiplying by x^2:

Integrate[
  x^2 (E^(-((x - 1)^2/(4 ϵ))) (Sqrt[π]))/ Sqrt[ϵ]
, {x, -∞, ∞}]

enter image description here

Sure enough, you get the expected result, and can now drop the ϵ regulator.

While ϵ>0 is a requirement for convergence, we can pick it to be as small as we like. Asymptotically, in the limit ϵ->+0 the result becomes indistinguishable from the one where ϵ is actually zero. This is what is implied when we say we "drop" the regulator. Additionally, recall that ϵ was not there initially and was introduced as a tool to be able to calculate. So at the end we certainly are looking for ways to minimize/remove the effect of ϵ to have an equality between initial and final expression where ϵ does not appear, in a consistent manner. That is what we do by "dropping" ϵ as described above.

$\endgroup$
  • $\begingroup$ Can you kindly base your "can now drop the ϵ regulator"? Pay your attention at Re[[Epsilon]>0]. $\endgroup$ – user64494 Jun 27 at 5:28
  • $\begingroup$ @user64494 I added some discussion to the answer. $\endgroup$ – Kagaratsch Jun 27 at 13:01
  • $\begingroup$ (1) Dropping the regulator is actually how one defines the generalized integral (the "usual" integral is divergent). You get an expression that has a limiting value, and define that limit as the generalized integral. (2) I liked (and upvoted) this answer. Just wanted to point out what it is that is being defined (you knew but I'm not sure it was clear). $\endgroup$ – Daniel Lichtblau Jun 28 at 16:16
1
$\begingroup$

After a variable substitition $x\to x+1$,

Sqrt[2π]*FourierTransform[(x + 1)^2, x, k]

Sqrt[2π] (Sqrt[2π] DiracDelta[k] - 2 I Sqrt[2π] DiracDelta'[k] - Sqrt[2π] DiracDelta''[k])

Integrate[%, {k, -∞, ∞}]

$\endgroup$
  • $\begingroup$ The integral Integrate[%, {k, -∞, ∞}] in the above makes no sense (e.g. see en.wikipedia.org/wiki/Dirac_delta_function ). $\endgroup$ – user64494 Jun 27 at 5:30
  • 3
    $\begingroup$ @user64494 Can you please give more details about why you think it makes no sense to integrate the Dirac $\delta$-distribution and its derivatives? From what I know, $\int_{-\infty}^{\infty}\delta(k)dk=1$ is a central property of this distribution, and $\int_{-\infty}^{\infty}\delta'(k)dk=\int_{-\infty}^{\infty}\delta''(k)dk=0$ as well. $\endgroup$ – Roman Jun 27 at 5:49

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.