MMa version of $\LaTeX$'s overtilde doesn't look as expected

Question

I am (mis)using Mathematica as a WYSIWYG LaTex editor. I want to put a (long) tilde over an expression.

DisplayForm[OverscriptBox[a + b, "_"]]
DisplayForm[OverscriptBox[a + b, "~"]]

This Is how it looks:

(Of course I'm using cntrl-7 to type in the above)

I want that the tilde stretched out over the whole expression, not just a small tilde in the middle. Just the same as with the underscore.

The corresponding LaTex expressions are

\overline{a+b}
\widetilde{a+b}

And the same issue with "^" and \widehat

I know I can mark the tilde (or hat) and use Command-"+" to increase the font size, but that doesn't look right.

Ideally, it would be something that exports easily to the mentioned Latex commands.

By the way,

FullForm[ToExpression["\\widetilde{a+b}", TeXForm]]

results in

OverTilde[Plus[a, b]]

which looks just like the above (tilde only above "+", not whole).

version: Mathematica 11.0

Edit/Clarification

I am well aware that this is not an issue with LaTeX itself, and that other, better working LaTeX editors exist. I want to continue writing Mathematica notebooks having parts which look like theorems or proofs look in math text books, referring to that look loosely as "LaTeX" (parts of which might later be exported for publication), and this question is about how to make those parts look right. So don't suggest any alternative LaTeX editors, that's not what the question is about.

Answer 1

Here is one rather hacky solution:

(* create a tilde graphics expression: *)
tilde = Graphics[
   First@First@ImportString[ExportString["~", "PDF"], "PDF"]];
tilde = Show[
   tilde,
   PlotRange -> Charting`get2DPlotRange@tilde,
   AspectRatio -> Full,
   BaseStyle :> CurrentValue@FontColor
   ];

MakeBoxes[WideOverTilde[expr_], frm_] ^:= With[
  {boxes = MakeBoxes[expr, frm]},
  With[
   {
    tildeBoxes = ToBoxes@Deploy@Dynamic@Show[
         tilde,
         ImageSize -> {
           FrontEndExecute[(* get the actual size of expr *)
             GetBoundingBoxSizePacket@Cell[
               BoxData@boxes,
               "Output",
               FontSize -> 1.4 CurrentValue@FontSize,
               PageWidth -> Infinity,
               CellMargins -> {{0, 0}, {0, 0}}
               ]][[1, 1]],
           5
           }
         ]
    },
   InterpretationBox[
    OverscriptBox[boxes, tildeBoxes],
    WideOverTilde[expr]
    ]
   ]
  ]

WideOverTilde["aaaaaaaaaaaaaa"]

Style[WideOverTilde[Sqrt[a + b]], Red, 30]

The basic idea is to stretch a tilde graphics expression to the correct width, and use that together with an OverScriptBox. The tild also inherits basic style properties from its surroundings, such as font color and size. Currently, the tilde graphics is just the standard tilde in the standard font, but you can probably create a graphics that's better suited.

Answer 2

$\widetilde{a+b}$

Maybe MMa's TeXForm doesn't do it properly, but it seems to work in MathJax. Or am I not understanding the question.