# Vector ParametricNDSolve and FindRoot interaction

This question came out of this question.

I have a set of differential equations, written in vector form. I'm only interested in the value of these at the endpoint, and so I use ParametricNDSolve, asking it to only return that function of the vectors. This works fine on its own, and is slightly quicker than asking for the whole solution to be returned:

Clear[test];
A = {{0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}, {q, 0, 0, 0}}; test =
ParametricNDSolveValue[{Y'[x] == A.Y[x], Y[0] == Table[1, 4]},
Y[4].Y[4], {x, 0, 4}, q];
First@AbsoluteTiming[test /@ Range[0, 10, 0.1];]
(* 0.037914 *)


However, if I try to use this same function in FindRoot, it now takes much longer to evaluate at the same points afterwards:

Clear[test];
A = {{0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}, {q, 0, 0, 0}}; test =
ParametricNDSolveValue[{Y'[x] == A.Y[x], Y[0] == Table[1, 4]},
Y[4].Y[4], {x, 0, 4}, q];
Quiet[FindRoot[test[q], {q, 3}]];
First@AbsoluteTiming[test /@ Range[0, 10, 0.1];]
(* 0.24924 *)


Which is 6 times longer than it took to do exactly the same calculation. Note that the function definition is identical, just the use of the function in the FindRoot has changed (which is also much slower than just getting the entire interpolation functions out and then calculating only the part I need).

Can anyone explain what is going on? I get the same timings on 11.3 and 12.0 on my mac.

• It somehow has to do with the "ParametricSensitivity". When you call FindRoot derivatives are computed from the parametric function and possibly stored (cached?) with the object. I do not know the exact details of why this would make the evaluation solver but you can avoid it by setting Method -> {"ParametricSensitivity" -> None} in ParametricNDSolve. This is not exactly my home turf, so if you need an answer and no one here knows that you may want to consider sending this to support. Jun 3, 2019 at 10:51
• @user21, thank you Jun 3, 2019 at 11:06
• @KraZug Think of an example in which FindRoot[] finds the root, and not just works in vain. Jun 4, 2019 at 4:31
• I reported this to Wolfram Support and they agreed it is a bug. The two fixes are potential workarounds. Jun 7, 2019 at 7:15

We can add a method, then the time is reduced by an order. In this example, the test-1000 has a root

Clear[test];
A = {{0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}, {q, 0, 0, 0}}; test =
ParametricNDSolveValue[{Y'[x] == A.Y[x], Y[0] == Table[1, 4]},
Y[4].Y[4], {x, 0, 4}, q];
Quiet[FindRoot[test[q] - 1000, {q,0,1}, Method -> "Secant"]];
First@AbsoluteTiming[test /@ Range[0, 10, 0.1];]
(*0.0341673*)


Compare without method and without FindRoot[]

 Clear[test];
A = {{0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}, {q, 0, 0, 0}}; test =
ParametricNDSolveValue[{Y'[x] == A.Y[x], Y[0] == Table[1, 4]},
Y[4].Y[4], {x, 0, 4}, q];
Quiet[FindRoot[test[q] - 1000, {q, 3}]];
First@AbsoluteTiming[test /@ Range[0, 10, 0.1];]

(*0.271661*)

Clear[test];
A = {{0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}, {q, 0, 0, 0}}; test =
ParametricNDSolveValue[{Y'[x] == A.Y[x], Y[0] == Table[1, 4]},
Y[4].Y[4], {x, 0, 4}, q];
First@AbsoluteTiming[test /@ Range[0, 10, 0.1];]

(* 0.0395219 *)


With the option Method -> "Secant" code works even faster than without FindRoot[].If we use the option Method -> "AffineCovariantNewton", then the time increases:

 Clear[test];
A = {{0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}, {q, 0, 0, 0}}; test =
ParametricNDSolveValue[{Y'[x] == A.Y[x], Y[0] == Table[1, 4]},
Y[4].Y[4], {x, 0, 4}, q];
Quiet[FindRoot[test[q] - 1000, {q, 1},
Method -> "AffineCovariantNewton"]];
First@AbsoluteTiming[test /@ Range[0, 10, 0.1];]

(* 0.298559 *)


Consequently, Newton's method (the default method) can slow down the code in this combination.

• Thank you, this is another workaround to go with the ParametricSensitivity option. I suspect that the slight speed increase in Method -> "Secant" will be due to the caching of the initial value of q=3. Jun 5, 2019 at 4:49