3
$\begingroup$

I have a complicated expression in function of 2 variables A and f that appears in all the possible combination. For example

a A^2 f + Tanh[c d] A f^2 +A^2 f^2 + 3 A f^3+ ....

and so on. I need to do a Series of this expression, neglecting

O(A^2 f^2).

I tried to Collect and then Series, but didn't work out.

Any ideas?

$\endgroup$
2
$\begingroup$

This isn't a well-defined question in the absence of further information. So I'll make some assumptions.

If $A$ and $f$ are the "same kind of small", then we can set $A=A_0x$ and $f=f_0x$, then series-expand in $x$:

Q = a A^2 f + Tanh[c d] A f^2 + A^2 f^2 + 3 A f^3;
Series[Q /. {A -> A0 x, f -> f0 x}, {x, 0, 3}]

$$ \left(a A_0^2 f_0+A_0 f_0^2 \tanh (c d)\right)x^3+O\left(x^4\right) $$

From this, the expression with higher-order terms dropped can be found with

Normal[%] /. {x -> 1, A0 -> A, f0 -> f}

$$ a A^2 f + A f^2 \tanh(c d) $$

If, on the other hand, $A$ is much smaller than $f$, we can for example set

Series[Q /. {A -> A0 x^2, f -> f0 x}, {x, 0, 5}]

$$ f_0^2 x^4 \tanh (c d)+x^5 \left(a A_0^2 f_0+3 A_0 f_0^3\right)+O\left(x^6\right) $$

Normal[%] /. {x -> 1, A0 -> A, f0 -> f}

$$ a A^2 f + 3 A f^3 + A f^2 \tanh(c d) $$

If, on the third hand, $f$ is much smaller than $A$, we can for example set

Series[Q /. {A -> A0 x, f -> f0 x^2}, {x, 0, 5}]

$$ a A_0^2 f_0 x^4+A_0 f_0^2 x^5 \tanh (c d)+O\left(x^6\right) $$

Normal[%] /. {x -> 1, A0 -> A, f0 -> f}

$$ a A^2 f + A f^2 \tanh(c d) $$

So you see it really depends on the relationship between $A$ and $f$. Many more relationships are possible, the above three examples are not exhaustive!

$\endgroup$
  • $\begingroup$ The first assumption was the right one, they are the same kind of small, sorry I forgot to specify! $\endgroup$ – rob May 29 at 13:24
  • $\begingroup$ @rob if they are the same kind of small, then you could also just substitute f -> y*A and then series-expand in A, and at the end back-substitute y -> f/A. $\endgroup$ – Roman May 29 at 15:51

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.