9
$\begingroup$

I am a new user of Mathematica, and just faced a problem. I have a data set of three columns, and want to select only those rows that go before the rows, which contain 0 in the third column. Eventually I want to create a new data set containing only these selected rows.

Can it be performed in Mathematica? Thank you in advance!

(edited)

$\endgroup$
15
$\begingroup$

You can use SequenceCases to define a pattern of two elements, the second of which has a 0 in the second column.

data = {{1, 2}, {8, 4}, {5, 0}, {3, 2}, {8, 9}, {7, 0}, {2, 3}};

SequenceCases[data, {a_, {___, 0}} :> a]
(* {{8, 4}, {8, 9}} *)

Here {a_, {___, 0}} is the pattern for two rows, and the :> a says that we want to extract the first part of the pattern.

$\endgroup$
  • $\begingroup$ Great solution! There's no need to name b, you can use the pattern {a_, {_, 0}} or even {a_, {___, 0}} (to be more flexible, see @kglr's comment below other solution). $\endgroup$ – Roman May 28 at 16:57
  • $\begingroup$ Thanks for the suggestions! $\endgroup$ – Jason B. May 28 at 17:10
13
$\begingroup$

You can also use ReplaceList:

data = {{1, 1, 2}, {2, 8, 4}, {3, 5, 0}, {4, 3, 2}, {5, 8, 9}, {6, 7, 0}, {7, 2, 3}};
ReplaceList[data, {___, a_, {__, 0}, ___} :> a]

{{2, 8, 4}, {5, 8, 9}}

Or combinations of

Extract and Position:

Extract[data, Position[data[[2 ;;, -1]], 0]]

{{2, 8, 4}, {5, 8, 9}}

PositionIndex and Part:

data[[PositionIndex[data[[2 ;;, -1]]][0]]]

{{2, 8, 4}, {5, 8, 9}}

$\endgroup$
  • $\begingroup$ Thank you a lot!! It works perfectly for my data set. I wonder now how the command Extract would work for 3 columns (zero value is in the 3rd column)? $\endgroup$ – Anna May 28 at 15:25
  • $\begingroup$ @Anna, made a small change ( replaced {_,0} with {__,0}) so that all methods should work for any number of columns (as long as the criterion is "the last column is of the next row is 0") $\endgroup$ – kglr May 28 at 15:50
  • $\begingroup$ @kglr For what it's worth: Cases[Split[data, #[[2]] != 0 &], {, a_, {, 0}} :> a] returns {} for me. $\endgroup$ – Christopher Lamb May 28 at 18:49
  • $\begingroup$ @ChristopherLamb, thank you; it is fixed now. $\endgroup$ – kglr May 28 at 18:58
7
$\begingroup$
data //Pick[Most@#, #[[2;;,3]],0]&

{{2, 8, 4}, {5, 8, 9}}

$\endgroup$
  • 1
    $\begingroup$ This is much faster than other methods posted for large input. (+1) $\endgroup$ – kglr May 29 at 6:55
3
$\begingroup$

Assuming we are interested in every row exactly preceding a row whose last entry (column) is equal to zero then it is possible to use Partition and its undocumented last argument.

In short, the last argument of Partition allows to apply a user defined function to every n-tuple of elements generated; eg. evaluating Partition[{1,2,3},2,1,{1,-1},Null] produces

{{1, 2}, {2, 3}}

while using the last argument and evaluating , Partition[{1,2,3},2,1,{1,-1},Null,f] produces

{f[1, 2], f[2, 3]}

where f can be any user-defined (or built-in, for that matter) function of an appropriate number of arguments.

Returning to the question, assuming data is a list of lists of three elements, then evaluating

Partition[data, 2, 1, {1, -1}, Null, If[#2[[-1]] == 0&&#1[[-1]] != 0, #1, Nothing] &]

should return the desired result.

{{-3,2,2},{1,2,2},{3,0,-3},{-2,-3,-2},{-2,1,-2},{2,3,2},
    {2,-1,2},{2,3,1},{2,3,-3},{0,1,2},{2,0,-3},{2,-3,-3}}

Please note how the second and third arguments to Partition instruct it to create pairs (2) of elements from the initial list that differ by one entry (1) while the fourth and fifth arguments are used to instruct Partition where in the new lists it should place the first and last element of the list and what to use for padding new lists, if needed (More details and examples are available at the documentation page for Partition).


Here are the example data used

BlockRandom[
  data = RandomVariate[DiscreteUniformDistribution[{-3, 3}], {100, 3}];
  RandomSeeding -> 123456789]
$\endgroup$
  • 1
    $\begingroup$ I used this feature in these q/a s. Btw, you can also use BlockMap[ If[#[[2,-1]] == 0&&#[[1,-1]] != 0, #[[1]], Nothing] &,data,2,1]; (+1) $\endgroup$ – kglr May 29 at 9:32
  • 1
    $\begingroup$ @kglr indeed it is the case that I learned about this feature from one of your answers; thanks for pointing out BlockMap $\endgroup$ – user42582 May 29 at 11:50

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.