1
$\begingroup$

I want to create a polar plot like this:

enter image description here

Which can not be made with the RevolutionPlot3D comand like here, it is because my function is dependent of the radius r and the angle Theta. I already tried with this code:

b = 0.042
m = 1
a = 0.1075
Gamma1 = 27.6561421691630044961129897274076938629150390625`50.
B1 = 10.8721158771190697933661795104853808879852294921875`50.
C1 = 1.0083854268623009264871370760374702513217926025390625`50.
D1 = 12.755787693798620097140883444808423519134521484375`50.
ParametricPlot3D[{(BesselJ[m, Gamma1*r] + 
      B1*BesselY[m, Gamma1*r] + C1*BesselI[m,Gamma1*r] + 
      D1*BesselK[m,Gamma1*r])*
    (Sin[m*Theta]+Cos[m*Theta])}, {Theta, 0, 2*Pi}, {r, b, a}]

I do not know why my code does not work.

$\endgroup$
4
  • $\begingroup$ Your function should be a vector-valued function to use ParameticPlot3D. $\endgroup$
    – Louis Yu
    Commented May 23, 2019 at 17:16
  • $\begingroup$ @L.Yu What do you mean by vector-valued function?. $\endgroup$
    – Alfredo
    Commented May 23, 2019 at 19:05
  • $\begingroup$ maybe ParametricPlot3D[{r Cos[ Theta], r Sin[Theta], (BesselJ[m, Gamma1*r] + B1*BesselY[m, Gamma1*r] + C1*BesselI[m, Gamma1*r] + D1*BesselK[m, Gamma1*r])*(Sin[m*Theta] + Cos[m*Theta])}, {Theta, 0, 2*Pi}, {r, b, a}, BoxRatios -> {1, 1, 1}]? $\endgroup$
    – kglr
    Commented May 23, 2019 at 19:10
  • $\begingroup$ Comment: an interesting surface, which appears to be topologically a cylinder. $\endgroup$
    – murray
    Commented May 24, 2019 at 14:11

1 Answer 1

1
$\begingroup$
ParametricPlot3D[{r Sin[Theta], r Cos[Theta],
   (BesselJ[m, Gamma1 r] + B1 BesselY[m, Gamma1 r] + 
     C1 BesselI[m, Gamma1 r] + D1 BesselK[m, Gamma1 r])*(Sin[m Theta] + Cos[m Theta])}, 
 {Theta, 0, 2 Pi}, {r, b, a}, Mesh -> {Range[0, 2 Pi, 2 Pi/20], 10}, 
 PlotStyle -> None, Boxed -> False, Axes -> False, BoxRatios -> 1, 
 BoundaryStyle -> Black]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.