# Why the function ScalingFunctions does not work?

Why highlighted in red and does not work function ScalingFunctions -> {None, "Reverse"} in ParametricPlot?

ParametricPlot[{0.06677273831511694*(1 - E^(-8.145*t)),
-0.10917030600597447*(1 - E^(-8.145*t)) + 1.2031921424186618*t},
{t, 0, 2.6}, PlotRange -> {{0, 0.07}, {0., 3.0191292643518968}},
AspectRatio -> 1, ScalingFunctions -> {None, "Reverse"}]

• The option is not implemented for ParametricPlot. Compare Options[Plot, ScalingFunctions] with Options[ParametricPlot, ScalingFunctions]. – Bob Hanlon May 20 '19 at 13:55

While ScalingFunctions is not documented to work with ParametricPlot, I think that is only because it fails when using it together with a PlotRange option. Take a look at the result of your ParametricPlot:

ParametricPlot[
{
0.06677273831511694*(1-E^(-8.145*t)),
-0.10917030600597447*(1-E^(-8.145*t))+1.2031921424186618*t
},
{t,0,2.6},
PlotRange->{{0,0.07},{0.,3.0191292643518968}},
AspectRatio->1,
ScalingFunctions->{None,"Reverse"}
] Notice that the vertical plot range is actually {0, -3} and not {0, 3}. So, either remove the PlotRange option:

ParametricPlot[
{
0.06677273831511694*(1-E^(-8.145*t)),
-0.10917030600597447*(1-E^(-8.145*t))+1.2031921424186618*t
},
{t,0,2.6},
AspectRatio->1,
ScalingFunctions->{None,"Reverse"}
] or modify it to reflect the transform being used:

ParametricPlot[
{
0.06677273831511694*(1-E^(-8.145*t)),
-0.10917030600597447*(1-E^(-8.145*t))+1.2031921424186618*t
},
{t,0,2.6},
PlotRange->{{0,0.07},{0.,-3.0191292643518968}},
AspectRatio->1,
ScalingFunctions->{None, "Reverse"}
] Another possibility is to use PlotRange -> All.

ScalingFunctions is not an option ParametricPlot.

To get the desired look, you can post-process the output of ParametricPlot to vertically flip the coordinates of line objects (using ScalingTransform[{1,-1}]) and reverse the vertical axis tick labels using ChartingScaledTicks["Reverse"]:

Show[ParametricPlot[{0.06677273831511694*(1 - E^(-8.145*t)),
-0.10917030600597447*(1 - E^(-8.145*t)) + 1.2031921424186618*t},
{t, 0, 2.6}, PlotRange -> {{0, 0.07}, {0., 3.0191292643518968}},
AspectRatio -> 1] /. Line[a_] :> Line[ScalingTransform[{1, -1}]@a],
PlotRange -> All,
Ticks -> {Automatic, ChartingScaledTicks["Reverse"]}] 