3
$\begingroup$

Why highlighted in red and does not work function ScalingFunctions -> {None, "Reverse"} in ParametricPlot?

ParametricPlot[{0.06677273831511694*(1 - E^(-8.145*t)),
  -0.10917030600597447*(1 - E^(-8.145*t)) + 1.2031921424186618*t},
 {t, 0, 2.6}, PlotRange -> {{0, 0.07}, {0., 3.0191292643518968`}},
 AspectRatio -> 1, ScalingFunctions -> {None, "Reverse"}]
$\endgroup$
  • $\begingroup$ The option is not implemented for ParametricPlot. Compare Options[Plot, ScalingFunctions] with Options[ParametricPlot, ScalingFunctions]. $\endgroup$ – Bob Hanlon May 20 at 13:55
6
$\begingroup$

While ScalingFunctions is not documented to work with ParametricPlot, I think that is only because it fails when using it together with a PlotRange option. Take a look at the result of your ParametricPlot:

ParametricPlot[
    {
    0.06677273831511694*(1-E^(-8.145*t)),
    -0.10917030600597447*(1-E^(-8.145*t))+1.2031921424186618*t
    },
    {t,0,2.6},
    PlotRange->{{0,0.07},{0.,3.0191292643518968`}},
    AspectRatio->1,
    ScalingFunctions->{None,"Reverse"}
]

enter image description here

Notice that the vertical plot range is actually {0, -3} and not {0, 3}. So, either remove the PlotRange option:

ParametricPlot[
    {
    0.06677273831511694*(1-E^(-8.145*t)),
    -0.10917030600597447*(1-E^(-8.145*t))+1.2031921424186618*t
    },
    {t,0,2.6},
    AspectRatio->1,
    ScalingFunctions->{None,"Reverse"}
]

enter image description here

or modify it to reflect the transform being used:

ParametricPlot[
    {
    0.06677273831511694*(1-E^(-8.145*t)),
    -0.10917030600597447*(1-E^(-8.145*t))+1.2031921424186618*t
    },
    {t,0,2.6},
    PlotRange->{{0,0.07},{0.,-3.0191292643518968`}},
    AspectRatio->1,
    ScalingFunctions->{None, "Reverse"}
]

enter image description here

Another possibility is to use PlotRange -> All.

$\endgroup$
3
$\begingroup$

ScalingFunctions is not an option ParametricPlot.

To get the desired look, you can post-process the output of ParametricPlot to vertically flip the coordinates of line objects (using ScalingTransform[{1,-1}]) and reverse the vertical axis tick labels using Charting`ScaledTicks["Reverse"]:

Show[ParametricPlot[{0.06677273831511694*(1 - E^(-8.145*t)),
      -0.10917030600597447*(1 - E^(-8.145*t)) + 1.2031921424186618*t},
    {t, 0, 2.6}, PlotRange -> {{0, 0.07}, {0., 3.0191292643518968`}},
    AspectRatio -> 1] /. Line[a_] :> Line[ScalingTransform[{1, -1}]@a], 
 PlotRange -> All, 
 Ticks -> {Automatic, Charting`ScaledTicks["Reverse"]}]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.