List of lists elementwise greater/smaller than

Question

I have two lists

a = {{3,1,2},{5,1,3},{4,1,1}}
b = {{4,0,3},{4,2,2},{5,0,2}}

And would like to compare each element within

If{a>b,1,0}

expecting the result

{{0,1,0},{1,0,1},{0,1,0}}

but it doesn't work, how can I get this type of comparison?

$\begingroup$ Strongly related $\endgroup$
– Leonid Shifrin
Commented May 18, 2019 at 18:57 — Leonid Shifrin, Commented May 18, 2019 at 18:57
$\begingroup$ you could use 1-UnitStep[b-a]? $\endgroup$
– kglr
Commented May 18, 2019 at 19:02 — kglr, Commented May 18, 2019 at 19:02
$\begingroup$ Of course, fixed. $\endgroup$
– Three Diag
Commented May 18, 2019 at 19:02 — Three Diag, Commented May 18, 2019 at 19:02
$\begingroup$ @kglr yep, that achieves the result, thanks $\endgroup$
– Three Diag
Commented May 18, 2019 at 19:05 — Three Diag, Commented May 18, 2019 at 19:05

kglr · Accepted Answer · 2019-05-18 19:06:31Z

11

Boole@Positive[a-b]

{{0, 1, 0}, {1, 0, 1}, {0, 1, 0}}

1-UnitStep[b-a]

{{0, 1, 0}, {1, 0, 1}, {0, 1, 0}}

answered May 18, 2019 at 19:06

kglr

399k18 gold badges486 silver badges920 bronze badges

Add a comment |

C. E. · Accepted Answer · 2019-05-18 19:13:03Z

3

kglr took the fast, vectorized operations. Here are some less optimal ones that you can have a look at for fun or for learning:

Boole@MapThread[Greater, {a, b}, 2]

{{0, 1, 0}, {1, 0, 1}, {0, 1, 0}}

Boole@Apply[Greater, Transpose[{a, b}, {3, 2, 1}], {2}]

{{0, 1, 0}, {1, 0, 1}, {0, 1, 0}}

answered May 18, 2019 at 19:13

C. E.

71k6 gold badges140 silver badges267 bronze badges

Add a comment |

eldo · Accepted Answer · 2024-04-16 00:13:53Z

2

a = {{3, 1, 2}, {5, 1, 3}, {4, 1, 1}};

b = {{4, 0, 3}, {4, 2, 2}, {5, 0, 2}};

Using Ramp (new in 11.0)

Ramp[a - b]

{{0, 1, 0}, {1, 0, 1}, {0, 1, 0}}

answered Apr 16 at 0:13

eldo

82.5k6 gold badges69 silver badges193 bronze badges

Add a comment |

3 Answers 3