What method cold I use to obtain a Plot similar to the one in the picture?
3
-
$\begingroup$ Have you already tried to plot something yourself? Generally you’ll get more bites if you actually tried something...posting the code you used aswell is helpful. $\endgroup$– DrMrstheMonarchCommented May 15, 2019 at 17:41
-
2$\begingroup$ Related: Pentagonal spiral in Mathematica. The figure you are asking for is actually produced in the question text of Filling Space with Pursuit Polygons, although the question is not really about this figure. $\endgroup$– C. E.Commented May 15, 2019 at 17:45
-
$\begingroup$ see also Drawing the Pursuit curves. $\endgroup$– AccidentalFourierTransformCommented May 15, 2019 at 19:50
Add a comment
|
3 Answers
$\begingroup$
$\endgroup$
Here is an adaptation of my answer here:
steps = Table[{r, 1.005 (2 Pi/4)}, {r, 1, 25, 0.2}];
Graphics[{Black, Line@AnglePath[steps]}, Background -> White]
The spiral tendency is controlled by the value 1.005 in the code, and the spacing between the lines is controlled by the value 0.2.
$\begingroup$
$\endgroup$
Not really an answer, since this isn't a single line but I thought it was interesting so I'll post it.
rc = Rectangle[];
center = {0.5, 0.5};
transforms = Table[
ScalingTransform[{x, x}, center] @* RotationTransform[(1 + -x) * Pi / 4, center],
{x, 1, 0.025, -0.025}
];
Graphics @ {EdgeForm @ Black, FaceForm @ None, GeometricTransformation[rc, transforms]}
answered May 15, 2019 at 18:09
$\begingroup$
$\endgroup$
1
Um, I like spirals. So as @C.E. points out, AnglePath is a useful function.
Manipulate[
Graphics[{Thick,
MapIndexed[{ColorData[cs, (#2[[1]]*d)^e], Line[#]} &,
Partition[AnglePath[Table[{r, a*Degree}, {r, 0, 1., d}]], 2, 1]]
}, Background -> Black, ImageSize -> 500],
{{d, 0.01, "Step Increment"}, 0.002, 0.02, Appearance -> "Labeled"},
{{a, 119., "Angle Increment (Degree)"}, 1., 180., Appearance -> "Labeled"},
{{e, 1.5, "Colour Exponent"}, 0.1, 3.0, Appearance -> "Labeled"},
{{cs, "SandyTerrain", "Colour Scheme"}, ColorData["Gradients"]}
]
-
$\begingroup$ There is an interesting optical illusion when scrolling this figure up and down quickly! $\endgroup$ Commented May 17, 2019 at 2:34