11
$\begingroup$

enter image description here

What method cold I use to obtain a Plot similar to the one in the picture?

$\endgroup$
3
20
$\begingroup$

Here is an adaptation of my answer here:

steps = Table[{r, 1.005 (2 Pi/4)}, {r, 1, 25, 0.2}];
Graphics[{Black, Line@AnglePath[steps]}, Background -> White]

Mathematica graphics

The spiral tendency is controlled by the value 1.005 in the code, and the spacing between the lines is controlled by the value 0.2.

$\endgroup$
11
$\begingroup$

Not really an answer, since this isn't a single line but I thought it was interesting so I'll post it.

rc = Rectangle[];
center = {0.5, 0.5};
transforms = Table[
    ScalingTransform[{x, x}, center] @* RotationTransform[(1 + -x) * Pi / 4, center],
    {x, 1, 0.025, -0.025}
];
Graphics @ {EdgeForm @ Black, FaceForm @ None, GeometricTransformation[rc, transforms]}

enter image description here

$\endgroup$
10
$\begingroup$

Um, I like spirals. So as @C.E. points out, AnglePath is a useful function.

 Manipulate[
    Graphics[{Thick,
       MapIndexed[{ColorData[cs, (#2[[1]]*d)^e], Line[#]} &,
          Partition[AnglePath[Table[{r, a*Degree}, {r, 0, 1., d}]], 2, 1]]
    }, Background -> Black, ImageSize -> 500],
    {{d, 0.01, "Step Increment"}, 0.002, 0.02, Appearance -> "Labeled"},
    {{a, 119., "Angle Increment (Degree)"}, 1., 180., Appearance -> "Labeled"},
    {{e, 1.5, "Colour Exponent"}, 0.1, 3.0, Appearance -> "Labeled"},
    {{cs, "SandyTerrain", "Colour Scheme"}, ColorData["Gradients"]}
 ]

spirals!

$\endgroup$
1
  • $\begingroup$ There is an interesting optical illusion when scrolling this figure up and down quickly! $\endgroup$ May 17 '19 at 2:34

This site is temporarily in read only mode and not accepting new answers.

Not the answer you're looking for? Browse other questions tagged .