Create a list of all possible Boolean configurations of three constraints

Question

I have three nonnegativity constraints \begin{equation} A_1>0, A_2>0, A_3>0. \end{equation} I want to create a single List consisting of all possible/inequivalent Boolean configurations of none (trivial), one (also trivial), two, and three of them, using the AND, NOT and OR operations.

How long will this List be?

Well--in response to the initial comment/answer--I was really thinking of a (multi-element) List such as

{B1 && B2 && ! B3, B1 || (B2 && B3), ! (B1 && B2) && B3,  B1 || (! B2 && B3), B1 || ! (B2 && B3), ! B1 && B2 && B3}

Given such a List, I would make the substitutions

{B1 -> A1 > 0, B2 -> A2 > 0, B3 -> A3 > 0}

and then attempt Boolean integrations using Boole[each element of the resulting list].

Answer 1

You can use BooleanCountingFunction:

exp = Array[Subscript[A, #] > 0 &, 3];
BooleanConvert[BooleanCountingFunction[{1}, 3] @@ exp]

TeXForm @ %

$\small\left(A_1\leq 0\land A_2\leq 0\land A_3>0\right)\lor \left(A_1\leq 0\land A_2>0\land A_3\leq 0\right)\lor \left(A_1>0\land A_2\leq 0\land A_3\leq 0\right)$

BooleanConvert[BooleanCountingFunction[{2}, 3] @@ exp] // TeXForm

$\small \left(A_1\leq 0\land A_2>0\land A_3>0\right)\lor \left(A_1>0\land A_2\leq 0\land A_3>0\right)\lor \left(A_1>0\land A_2>0\land A_3\leq 0\right)$

BooleanConvert[BooleanCountingFunction[{3}, 3] @@ exp] // TeXForm

$\small A_1>0\land A_2>0\land A_3>0$

Answer 2

You can create a list of all 8 possible combinations:

tups = Tuples[And[{B1, !B1}, {B2, !B2}, {B3, !B3}]]

{B1 && B2 && B3, B1 && B2 && ! B3, B1 && ! B2 && B3, B1 && ! B2 && ! B3, ! B1 && B2 && B3, ! B1 && B2 && ! B3, ! B1 && ! B2 && B3, ! B1 && ! B2 && ! B3}

Then, I think you want the power set:

sets = BooleanMinimize /@ Subsets[Or @@ tups];
sets[[;;20]]

{False, B1 && B2 && B3, B1 && B2 && ! B3, B1 && ! B2 && B3, B1 && ! B2 && ! B3, ! B1 && B2 && B3, ! B1 && B2 && ! B3, ! B1 && ! B2 && B3, ! B1 && ! B2 && ! B3, B1 && B2, B1 && B3, (B1 && B2 && B3) || (B1 && ! B2 && ! B3), B2 && B3, (B1 && B2 && B3) || (! B1 && B2 && ! B3), (B1 && B2 && B3) || (! B1 && ! B2 && B3), (B1 && B2 && B3) || (! B1 && ! B2 && ! B3), (B1 && B2 && ! B3) || (B1 && ! B2 && B3), B1 && ! B3, (B1 && B2 && ! B3) || (! B1 && B2 && B3), B2 && ! B3}

You examples are all included:

examples = {
    B1 && B2 && ! B3,
    B1 || (B2 && B3),
    ! (B1 && B2) && B3, 
    B1 || (! B2 && B3),
    B1 || ! (B2 && B3),
    ! B1 && B2 && B3
};
MemberQ[sets, #]& /@ BooleanMinimize /@ examples

{True, True, True, True, True, True}