Exponential generating function

Question

I need to find the $m^\text{th}$ term for the following expression:

$$ \left.\frac{\partial^m}{\partial t^m}e^{a t^2}\right|_{t=0}$$ I computed first few terms and used mathematica "FindSequenceFunction", which yielded the $m^\text{th}$ term as:

$$ \frac{2^{m-1} \left(1+(-1)^{m}\right) a^{\frac{m}{2}} \Gamma \left(\frac{m+1}{2}\right)}{\sqrt{\pi }}$$

Question 1: Instead of following the above approach, I want to follow a direct approach:

res = D[Exp[a t^2], {t, m}]
res1 = res /. {t -> 0}
FullSimplify[%]

The corresponding three outputs are: $$\sqrt{\pi } 2^m t^{-m} \, _2\tilde{F}_2\left(\frac{1}{2},1;\frac{1}{2} (-m-1)+1,1-\frac{m}{2};a t^2\right)$$

$$\frac{\sqrt{\pi } 0^{-m}}{\Gamma \left(\frac{1-m}{2}\right) \Gamma \left(\frac{2-m}{2}\right)}$$ $$\frac{0^{-m}}{\Gamma (1-m)}$$

Since $a$ is not present in the answer, hence it is not correct.

Question 2: Hermite polynomial generating function:

resh = D[Exp[x t - t^2/2], {t, m}]
resh1 = resh /. {t -> 0}
FullSimplify[%]

The outputs are:

Any suggestion on how to proceed further in this regard will be appreciated.

Answer 1

You can use SeriesCoefficient:

term[m_] = SeriesCoefficient[m! Exp[a t^2], {t, 0, m}];
term[m] //TeXForm

$\begin{cases} \frac{m! a^{m/2}}{\frac{m}{2}!} & (m \bmod 2)=0\land m\geq 0 \\ 0 & \text{True} \end{cases}$

Check:

term /@ Range[6, 10]
Table[D[Exp[a t^2], {t, m}] /. t->0, {m, 6, 10}]

{120 a^3, 0, 1680 a^4, 0, 30240 a^5}

{120 a^3, 0, 1680 a^4, 0, 30240 a^5}

Answer 2

Another ways:

ClearAll["`*"]


A = Limit[InverseMellinTransform[
D[MellinTransform[Exp[a t^2], a, s], {t, m}] // FunctionExpand // 
PowerExpand, s, a], t -> 0, Direction -> -1]
Table[A, {m, 6, 10}]

(*{120 a^3, 0, 1680 a^4, 0, 30240 a^5}*)

B = InverseLaplaceTransform[
Simplify[D[LaplaceTransform[Exp[a t^2], a, s], {t, m}], m > 1] /. 
t -> 0, s, a] // FullSimplify
Table[B, {m, 6, 10}]

(*{120 a^3, 0, 1680 a^4, 0, 30240 a^5}*)

f[t_] := Exp[a t^2];
c = Table[D[f[t], {t, m}], {m, 10}];
FindSequenceFunction[Limit[c, t -> 0], m]
(*(2^(-1 + m) (1 + (-1)^m) a^(m/2) Gamma[1/2 + m/2])/Sqrt[\[Pi]]*)

Table[%, {m, 6, 10}]
(*{120 a^3, 0, 1680 a^4, 0, 30240 a^5}*)


Table[m!*InverseZTransform[Exp[a t^2] /. t -> 1/t, t, m], {m, 6, 10}]
(*{120 a^3, 0, 1680 a^4, 0, 30240 a^5}*)