How to generate two non-overlapping LogNormalDistribution and their CDF?

Question

I'd like to know how to generate two LogNormalDistribution with the same standart deviation and, if possible, get the associated CDF.

To contextualize, I'm trying to reproduce this plot:

Reference of the paper: https://www.sciencedirect.com/science/article/pii/S0031920106001610

Thanks in advance

Note: This plot was obtanied by numerically solving the equations $M(t) = M_{eq} -(M_{eq}-M_0) e^{-t/\tau}$, with $M_0$ = 0, $M_{eq}$ = 1 and I supposed that (although I don't know how to do it) the $\tau$ distributions was used as an input. The objective of the plot is to show that independently of the $\tau$ distribution, the resultant plot of $M(t) / M_{eq}$ is almost the same

Answer 1

LogNormalDistribution is a built-in distribution so you can use PDF and CDF.

Plot[
 {PDF[LogNormalDistribution[1, 0.25], x],
  8 PDF[LogNormalDistribution[3, 0.25], x], 
  CDF[LogNormalDistribution[1, 0.25], x] + 
  CDF[LogNormalDistribution[3, 0.25], x]},
 {x, 0, 200},
 PlotRange -> {-0.01, 2},
 ScalingFunctions -> {"Log", None}
]

Answer 2

I understand that the point is how much the variability of the $\tau$ parameter will affect the shape of the $M(t)=M_0\cdot E^{-t/\tau}$ function.

$\tau$ obay a certain probability distribution. We nead to obtain $\tau$ values for the probabilities $p$ that set the boundaries of ever wider confidence intervals. This is done using InverseCDF[]. I have selected the fallowing probabilities: {0.125,0.25,0.375,0.5,0.625,0.75,0.875}. For respectve $\tau$ values, we define the function $M(t)$.

Now, instead of a single $M(t)$ function, we plot a family of functions that differ in the $\tau$ parameter, so that the 'central'* function (the one with $p=0.5$) is marked in black and its less and less likely variants are gray.

Such a plots ware crated for the $\tau$ obaying the LogNormalDistribution[μ,σ]** - where different values of $\mu$ and $\sigma$ were tried.

pp = Table[i, {i, 0.125, 1 - 0.125, 0.125}]
\[Mu]\[Mu] = Table[i, {i, 1, 5, 1}];
\[Sigma]\[Sigma] = {0.5, 1, 2};
dist1 := LogNormalDistribution[\[Mu], \[Sigma]]
\[Tau][p_] := InverseCDF[dist1, p]
M[t_, p_] := E^(-t/\[Tau][p])
MM := Table[M[t, p], {p, pp}]
rowh = Table[StringJoin["\[Mu]=", ToString[i]], {i, \[Mu]\[Mu]}];
colh = Table[
   StringJoin["\[Sigma]=", ToString[i]], {i, \[Sigma]\[Sigma]}];
TableForm[
 Table[Plot[MM, {t, 0, 25}, 
   PlotStyle -> {Gray, Gray, Gray, Black, Gray, Gray, Gray}, 
   Filling -> {1 -> {7}, 2 -> {6}, 3 -> {5}}, 
   FillingStyle -> {Gray, Opacity[0.5]}, 
   PlotRange -> {0, 
     1}], {\[Mu], \[Mu]\[Mu]}, {\[Sigma], \[Sigma]\[Sigma]}], 
 TableHeadings -> {rowh, colh}]

Similarly for NormalDistribution[μ,σ], but here some of $\tau$'s fell below $0$ causing exponential explosion of $M$.

*) Please note that this one corresponds to the median of the $\tau$ distribution and not to mode (the most probable value).

**) Please pay attention to the meaning of parameters in log-normal distribution - they are non-trivial!