1
$\begingroup$

I'm trying to obtain the Laurent Series of $f(z)=\frac{z}{(z+1)(z-2)}$ about $z=-1$ in the annular region $|z+1|>3$. I've been trying to use the following code

Series[z/((z + 1) (z - 2)), {z, -1, 10}, Assumptions -> (Abs[z + 1] > 3)]

but it always returns the Laurent Series defined in the region $0<|z+1|<3$. Am I doing something incorrectly?

$\endgroup$
  • 1
    $\begingroup$ So I'm not sure if this is quite right (my complex analysis here is a little rusty), but I think you can do Normal@Series[ z/((z + 1) (z - 2)) /. z -> z - 1 // Evaluate, {z, \[Infinity], 5}] /. z -> z + 1. This shifts the pole from -1 to 0, expands about infinity rather than 0, and then shifts z back to z-1. $\endgroup$ – march May 1 at 21:16
2
$\begingroup$

I think this can be done by expanding around infinity. This gives a power series in (for example z^-1). To get a power series in (z-1)^-1 requires a change of variable.

expr = z/((z + 1) (z - 2));

ser = Series[expr /. z -> w - 1, {w, \[Infinity], 5}]

(* SeriesData[w, DirectedInfinity[1], {1, 2, 6, 18, 54}, 1, 6, 1] *)

Normal[ser] /. w -> z + 1

(* 54/(1 + z)^5 + 18/(1 + z)^4 + 6/(1 + z)^3 + 2/(1 + z)^2 + 1/(1 + z) *)

I hope this is correct, my memory of Laurent series has faded a little.

$\endgroup$
  • $\begingroup$ The code certainly supplies the same answer as I get when I do it by hand. Do you mind explaining in a bit more detail how it works, and how this technique would be used in general? $\endgroup$ – David May 1 at 21:32
1
$\begingroup$

A variation of mikado's answer is the following:

Series[z/((z + 1) (z - 2)) /. z->-1 + Defer[z+1], {Defer[z+1], Infinity, 10}] //TeXForm

$\frac{1}{z+1}+\frac{2}{(z+1)^2}+\frac{6}{(z+1)^3}+\frac{18}{(z+1)^4}+\frac{54}{(z+1)^5}+\frac{162}{(z+1)^6}+\frac{486}{(z+1)^7}+\frac{1458}{(z+1)^8}+\frac{4374}{(z+1)^9}+\frac {13122}{(z+1)^{10}}+O\left(\left(\frac{1}{z+1}\right)^{11}\right)$

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.