0
$\begingroup$

How can I compute this integral for $y\rightarrow0$ ?

$$ \int_0^1{\frac{y(1-x)^2(1+x)}{x+(1-x^2)y} dx} $$

$\endgroup$

closed as off-topic by corey979, Roman, Michael E2, xzczd, AccidentalFourierTransform May 1 at 14:39

  • The question does not concern the technical computing software Mathematica by Wolfram Research. Please see the help center to find out about the topics that can be asked here.
If this question can be reworded to fit the rules in the help center, please edit the question.

  • $\begingroup$ Did you really mean to ask this here since you also posted on Math.SE? $\endgroup$ – StubbornAtom May 1 at 10:19
  • $\begingroup$ Am I missing something? The integrand clearly goes to 0 as y approaches zero. $\endgroup$ – infinitezero May 1 at 13:26
  • 1
    $\begingroup$ @infinitezero It seems there are some doubts about order of limits in y->0 and x close to zero. Doing x integral first and then taking y->0 does give the expected zero of course. $\endgroup$ – Kagaratsch May 1 at 13:30
2
$\begingroup$
Assuming[y > 0, 
  AsymptoticIntegrate[(y (1 - x)^2 (1 + x))/(x + (1 - x^2) y), {x, 0, 1}, {y, 0, 1}]]

1/6 y (-7 - 6 Log[y])

So the limit for $y\to0^+$ is zero:

Limit[%, y -> 0, Direction -> "FromAbove"]

0

For $y<0$ the integral does not converge.

$\endgroup$
  • $\begingroup$ Is there a way to achieve the same result but analytically? $\endgroup$ – Luca Rossi May 1 at 9:30
  • $\begingroup$ Integrate[(y (1 - x)^2 (1 + x))/(x + (1 - x^2) y), {x, 0, 1}, Assumptions -> y > 0] maybe, although the above is already analytic. $\endgroup$ – Roman May 1 at 9:33
1
$\begingroup$

Another approach if you want to avoid the use of AsymptoticIntegrate (whose very presence I learnt today, thanks @Roman:-)!).

Timing[
 FullSimplify[
  Integrate[(y (1 - x)^2 (1 + x))/(x + (1 - x^2) y), {x, 0, 1}, 
   Assumptions -> y > 0], y > 0]]
(* {6.64063, ((-2 + y) y Sqrt[1 + 4 y^2] - (-1 + y) Sqrt[
   1 + 4 y^2]
    Log[y] + (1 - 2 y) y Log[(1 + 2 y - Sqrt[1 + 4 y^2])/(
    1 + 2 y + Sqrt[1 + 4 y^2])] + 
  Log[(1 + 2 y + Sqrt[1 + 4 y^2])/(1 + 2 y - Sqrt[1 + 4 y^2])])/(
 2 y^2 Sqrt[1 + 4 y^2])} *)

Normal[
  Series[(1/(
   2 y^2 Sqrt[
    1 + 4 y^2]))((-2 + y) y Sqrt[1 + 4 y^2] - (-1 + y) Sqrt[1 + 4 y^2]
       Log[y] + (1 - 2 y) y Log[(1 + 2 y - Sqrt[1 + 4 y^2])/(
       1 + 2 y + Sqrt[1 + 4 y^2])] + 
     Log[(1 + 2 y + Sqrt[1 + 4 y^2])/(
      1 + 2 y - Sqrt[1 + 4 y^2])]), {y, 0, 1}]] // 
 FullSimplify[#, y > 0] &
(* -(1/6) y (7 + 6 Log[y]) *)
$\endgroup$
0
$\begingroup$

The OP asked whether there is a way to achieve the result "analytically", which I assume implies "by steps that can be considered a proof by humans". Here is an attempt.

Define integrand

integrand = (y (1 - x)^2 (1 + x))/(x + (1 - x^2) y);

For any y>0 we see that there is no pole on the interval 1>x>0, which means we can obtain the integral over this region using the fundamental theorem of calculus by taking a difference of anti-derivatives evaluated at the boundary points.

First we may "guess" an anti-derivative:

antiderivative = Assuming[y > 0, Integrate[integrand, x] // Simplify]

enter image description here

to prove that this is in fact a valid anti-derivative, simply take the derivative which is a simple mechanical process and can be done either by hand or as:

D[antiderivative, x] - integrand // Simplify

0

Having proven that we in fact have a correct anti-derivative, we evaluate it at the boundary points and take a difference:

integral = (antiderivative /. x -> 1) - (antiderivative /. x -> 0) // FullSimplify

enter image description here

Finally, we take a series expansion of this result around the point y=0 to figure out its leading behavior:

Assuming[y > 0, Series[integral, {y, 0, 0}]]

enter image description here

This means that the integral result vanishes at least linearly in y->0 so that the integral is zero in that limit.

Note that the derivative to prove the anti-derivative, the evaluation at x=1 and x=0, and the Taylor expansion around y=0 all can be done by hand on a piece of paper, which makes the steps humanly traceable and therefore constitutes a proof.

$\endgroup$

Not the answer you're looking for? Browse other questions tagged or ask your own question.