How do I fill a table with values from my function?

Question

With the following function,

 PoissonBinomialSuccess[plist_, t_] := Flatten[With[{n = Length@plist, c = Exp[(2 I \[Pi])/(Length@plist + 1)]}, success = Probability[{k >= t}, k \[Distributed] (ProbabilityDistribution[Re[1/(n + 1) Sum[c^(-l k) Product[1 + (c^l - 1) plist[[m]], {m, 1, n}], {l,0, n}]], {k, 0, n, 1} ])]]] /; AllTrue[plist, 0 <= # <= 1 &]

I wish to populate a table with outputs by that function. For example, defining $plist$ and $t$ as shown below, I would like to create a table. The purpose is to create a 3D plot.

Edit / Clarification: I am only interested in the information that I have indicated by the square (so, the headings are unimportant). Also, the plists are vectors of homogeneous probabilities, that increment by some fixed magnitude. For example {0, 0, 0, 0, 0}, {0.1, 0.1, 0.1, 0.1, 0.1}, {0.2, 0.2, 0.2, 0.2, 0.2}, ... {1, 1, 1, 1, 1}.

For example, using @Bob Hanlon's approach below, the following is what I image. But I am very surprised that it appears problematic to display a 3D plot of the content:

TableForm[ table = Outer[PoissonBinomialSuccess[#1, #2][[1]] &, plist, tlist, 1]]

Answer 1

Look at documentation for Outer

PoissonBinomialSuccess[plist_, t_] :=
 Flatten[
   With[{
     n = Length@plist,
     c = Exp[(2 I π)/(Length@plist + 1)]},
    success = Probability[{k >= t},
      k \[Distributed] (ProbabilityDistribution[Re[1/(n + 1)* 
           Sum[
            c^(-l k)* 
             Product[
              1 + (c^l - 1) plist[[m]],
              {m, 1, n}],
            {l, 0, n}]],
         {k, 0, n, 1}])]]] /;
  AllTrue[plist, 0 <= # <= 1 &]

EDIT:

plist = ConstantArray[#, 5] & /@ Range[0, 1, .1];

tlist = Range[5];

TableForm[
 table = Outer[
   PoissonBinomialSuccess[#1, #2][[1]] &,
   plist, tlist, 1],
 TableHeadings -> {
   StringForm["plist=``", #] & /@ plist,
   StringForm["t=``", #] & /@ tlist},
 TableAlignments -> {".", Center}]

EDIT 2:

ListPlot3D[Table[
   {p, t, PoissonBinomialSuccess[ConstantArray[p, 5], t][[1]]},
   {p, 0, 1, .05}, {t, Range[5]}] // Flatten[#, 1] &,
 AxesLabel -> (Style[#, 12, Bold] & /@{"p", "t", "Success"})]