0
$\begingroup$

I have the following parametric plot:

ParametricPlot[{u + 2800*v, v}, {u, -1/2, 1/2}, {v, -4, 4}, 
  PlotRange -> {{-4, 4}, {-1/1000, 1/1000}}, AspectRatio -> 1, 
  AxesLabel -> {"x", "x'"}] 

I now wish to restrict the x coordinates as $-3/2 \leq x \leq 3/2$. In other words only the part of the region for which $-3/2 \leq u + 2800 v \leq 3/2$ holds, is the desired region, see illustration below. How can I implement this? enter image description here

$\endgroup$
  • 1
    $\begingroup$ To restrict to a region, add the option RegionFunction -> Function[{u, v}, -(3/2) <= u + 2800 v <= 3/2] to your ParametricPlot (however, this seems to end up plotting nothing, so I'm not sure whether this set of parameters makes sense?) $\endgroup$ – march Apr 26 '19 at 3:21
  • $\begingroup$ Thanks for the suggestion, your suggestion is indeed what I am looking for I suppose, but trying it this way, I end up with nothing as well. $\endgroup$ – Robin Egberts Apr 26 '19 at 12:00
1
$\begingroup$

Maybe you can use ParametricRegion instead:

reg = ParametricRegion[
    {{u + 2800 v, v}, -3/2 < u + 2800 v < 3/2},
    {{u,-1/2,1/2}, {v,-4,4}}
];

Then, you can create your desired graphics with:

Show[
    Region@reg,
    PlotRange -> {{-4, 4}, {-2/1000, 2/1000}},
    AspectRatio -> 1, 
    AxesLabel -> {"x", "x'"},
    Frame -> True,
    Axes->True
]

enter image description here

Another possibility is to use a region specification for the parameters:

region = RegionIntersection[
    Rectangle[{-1/2, -4}, {1/2, 4}],
    ImplicitRegion[-3/2 < u + 2800 v < 3/2, {u, v}]
];
ParametricPlot[
    {u + 2800 v, v},
    {u, v} ∈ region,
    PlotRange -> {{-5, 5}, {-2/1000, 2/1000}},
    AspectRatio -> 1,
    AxesLabel -> {"x", "x'"}
]

enter image description here

| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.