2
$\begingroup$

I know this kind of question is frequent asked, yet each case has its own particularities. I will show my problem.

I define the following:

f[k_] := Binomial[n, k] (Sin[Φ]^2)^k (Cos[Φ]^2)^(n - k);
g[k_] := 2 (f[n - k - 1] (k + 1) - f[n - k] k);

After that I want to perform the sum:

FullSimplify[Tan[Φ]^2*Sum[g[k]^2/f[n - k], {k, 0, n}],
Element[n, Integers] && n > 0 && Element[Φ, Reals] && 0 < Φ < Pi/2]

And I got the result:

4 n^2 Cos[Φ]^2 HypergeometricPFQ[{-n,1-n/2-1/2 n Cos[2 Φ],1-n/2- 
1/2 n Cos[2 Φ]},{-n Cos[Φ]^2,-n Cos[Φ]^2},-Cot[Φ]^2] Sin[Φ]^(-2+2 n)

This as much as I can simplify the expression. However, according to book the result of the sum is just 4n

H[n_]=Tan[Φ]^2*Sum[g[k]^2/f[n - k], {k, 0, n}]]//FullSimplify

Table[H[i],{i,1,10}]//FullSimplify
{4, 8, 12, 16, 20, 24, 28, 32, 36, 40}

If I introduce the Assumptions in the following way at the beginning of the notebook:

$Assumptions = n ∈ Integers && n < 100 && 
  n > 0 && Φ ∈ Reals && 0 < Φ < Pi/2

The result of the simplification is yet worse.

The problem is that I have to perform some summations similar to this, but this time I don't have previous knowledge of the solution

$\endgroup$
4
$\begingroup$

Eliminating the trigonometric terms work in this case:

expr = 4 n^2 Cos[Φ]^2 HypergeometricPFQ[{-n,1-n/2-1/2 n Cos[2 Φ],1-n/2- 
  1/2 n Cos[2 Φ]},{-n Cos[Φ]^2,-n Cos[Φ]^2},-Cot[Φ]^2] Sin[Φ]^(-2+2 n);

FullSimplify[expr /. Φ -> ArcCos[q], 0 < q < 1]
4n
$\endgroup$
3
$\begingroup$
Clear["Global`*"];

$Assumptions =
  Element[n, Integers] && n > 0 && 0 < Φ < Pi/2;

f[k_] := Binomial[n, k] (Sin[Φ]^2)^
    k (Cos[Φ]^2)^(n - k);
g[k_] := 2 (f[n - k - 1] (k + 1) - f[n - k] k);

seq = Table[
  Tan[Φ]^2*Sum[g[k]^2/f[n - k], {k, 0, n}] // Simplify,
  {n, 1, 10}]

(* {4, 8, 12, 16, 20, 24, 28, 32, 36, 40} *)

Using FindSequenceFunction,

H[n_] = FindSequenceFunction[seq, n]

(* 4 n *)

Verifying over wider range,

And @@ Table[
  H[n] == Tan[Φ]^2*Sum[g[k]^2/f[n - k], {k, 0, n}] // Simplify, {n,
    1, 25}]

(* True *)
$\endgroup$
  • $\begingroup$ Thank, that's very useful answer. That function may be helpful $\endgroup$ – Popeye Apr 24 at 17:14

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.