ListPolarPlot Marker and Labelling

Question

I have a list of data points to plot. These points all have the same radius of 1. The angles are different generally speaking, but it is possible some points can have the same angle, or the same angle after modulo 360 degrees. In that case, two points would overlap each other. For example,

data = {{0, 1}, {5 Pi/6, 1}, {8 Pi/3, 1}, {7 Pi/2, 1}, {10 Pi/3, 
    1}, {25 Pi/6, 1}, {6 Pi, 1}, {41 Pi/6, 1}, {20 Pi/3, 1}, {15 Pi/2,
     1}, {28 Pi/3, 1}, {61 Pi/6, 1}};

ListPolarPlot[data]

gives the following plot, which appears to be 6 points. Actually, they are 12 points and there 2 points overlapping each other everywhere.

My question is, how to label these points consecutively with numbers from 1 to 12 to indicate the sequence in which they appear in the data list and also change the marker of a point if it is overlapping a previous point? For example, the 7th point will be overlapping the 1st point in data, so its marker will be changed to a different shape than the dot, maybe an "x".

Answer 1

The following may look complicated, but the pattern for creating the counter in label is actually quite common and is good to learn (if you don't already know it.)

label[data_, acc_: 0.0001] := Module[{c},
  c[_] = 0;
  ++c[{
       Round[Mod[First[N@#], 2 Pi], acc],
       Round[Last[N@#], acc]
       }] & /@ data
  ]

labels = label[data];
groups = Map[Last, GatherBy[Transpose[{labels, data}], First], {2}];

ListPolarPlot[groups, PlotMarkers -> {"OpenMarkers", Large}]

For labels, you can do:

first = First[groups];

Show[
 ListPolarPlot[first -> Range@Length@first],
 ListPolarPlot[groups, PlotMarkers -> {"OpenMarkers", Large}]
 ]