1
$\begingroup$

Using this command I can plot three different curves using ParametricPlot3D

ParametricPlot3D[{{t x, Sin[t x], 0}, {0 , Sin[t x], t x }, {t x ,Sin[t x], t x }}, {t, 0, Pi}, {x, 0, 4}]

However, my output result is coming out crooked. How can I fix it? The command ViewPoint does not work as in Plot3D or DensityPlot, There are some specific commands?

The idea is to obtain something like that. This plot was generated using my code. but it was obtained using paint. The resolution is awful.

enter image description here

Improve this question
$\endgroup$
2
  • $\begingroup$ What do you mean ViewPoint does not work? Can you give us an example where ViewPoint works in Plot3D, but it does not work in ParametricPlot3D? $\endgroup$
    – ktm
    Apr 22, 2019 at 13:30
  • 1
    $\begingroup$ Perhaps you mean ViewVertical? Also consider reparametrizing to 1 variable so the plotter knows it's actually a 1D curve: ParametricPlot3D[{{s, Sin[s], 0}, {0, Sin[s], s}, {s, Sin[s], s}}, {s, 0, 4 Pi}, Lighting -> "Neutral", ViewVertical -> {0, -1, 0}, ViewPoint -> {1.4, -1.3, -2.8}, ImageSize -> 700] /. Line -> Tube $\endgroup$
    – Greg Hurst
    Apr 22, 2019 at 13:31

3 Answers 3

Reset to default
1
$\begingroup$

To add to Chips answer, sometimes the option AxesEdge is helpful and a few other clues in case someone isn't sure which axis is which:

ParametricPlot3D[{{t x, Sin[t x], 0}, {0, Sin[t x], t x}, {t x, Sin[t x], t x}}, {t, 0, Pi}, {x, 0, 4}, Boxed -> False, AxesLabel -> {x, y, z}, AxesEdge -> {{0, 2}, {0, 3}, {0, 4}}, AxesStyle -> {Red, Green, Blue}]

Improve this answer
$\endgroup$
1
$\begingroup$ 
ParametricPlot3D[{{s, 0, Sin[s]}, {0, s, Sin[s]}, {s, s, Sin[s]}}, {s, 0, 4 Pi}, 
  PlotStyle -> Tube[.07], ImageSize -> Large]

enter image description here

Improve this answer
$\endgroup$
0
$\begingroup$ 
axes[x_, y_, z_, f_, a_] := 
 Graphics3D[
  Join[{Red, Arrowheads[a]}, 
   Arrow[Tube[{{0, 0, 0}, #}]] & /@ {{x, 0, 0}, {0, y, 0}, {0, 0, 
      z}}, {Text[
     Style["x", FontSize -> Scaled[f]], {0.9*x, 0.1*y, 0.1*z}], 
    Text[Style["y", FontSize -> Scaled[f]], {0.1 x, 0.9*y, 0.1*z}], 
    Text[Style["z", FontSize -> Scaled[f]], {0.1*x, 0.1*y, 0.9*z}]}]]
Show[{(ParametricPlot3D[{{s, Sin[s], 0}, {0, Sin[s], s}, {s, Sin[s], 
       s}}, {s, 0, 4 Pi}, Lighting -> "Neutral", ImageSize -> 700] /. 
    Line -> Tube), axes[10, 10, 10, 0.05, 0.02]}, 
 PlotRange -> {{-5, 10}, {-5, 10}, {-5, 10}}, 
 ViewVertical -> {0, 0, 1}, ViewPoint -> {Pi, Pi/2, 2}, 
 AxesOrigin -> {0, 0, 0}]
Improve this answer
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.