Finding the area between two curves with Integrate

Question

I'm trying to solve and approximate the area between the two graphs. Right now, my functions are stored as

f[x_] := 3 Sin[x]
g[x_] := x - 1

and then I tried to integrate by evaluating

Integrate[Abs[f[x] - g[x]], x]

Instead of getting an answer, I just get the exact same thing I inputted

Integrate[Abs[f[x] - g[x]], x]

How do I fix this?

Answer 1

Use Assumptions:

Integrate[Abs[f[x] - g[x]], x, Assumptions -> x \[Element] Reals]

Or try RealAbs instead of Abs:

Integrate[RealAbs[f[x] - g[x]], x]

(They are equivalent antiderivatives.)

To get the area between the graphs, you need also to solve for the points of intersection.

area = Integrate[
 Abs[f[x] - g[x]], {x, Sequence @@ MinMax[x /. Solve[f[x] == g[x], x, Reals]]}]

The area is approximately:

N[area]
(*  5.57475  *)

Answer 2

You need to add assumptions, like this

 Integrate[Abs[f[x] - g[x]], x, Assumptions :> Element[x, Reals]]

Answer 3

Assuming your functions

f[x_] := 3 Sin[x] 
g[x_] := x - 1

are real valued, you can use square root of square to parametrize the absolute value. This then gives:

Integrate[Sqrt[(f[x] - g[x])^2], x]

(((-2 + x) x + 6 Cos[x]) Sqrt[(-1 + x - 3 Sin[x])^2])/(2 (-1 + x - 3 Sin[x]))