0
$\begingroup$

can help to graph on z-axis

NDSolve[{f''''[z] + f'''[z] + 1000 f''[z] == 1, y[-(1/2)] == 0, y[1/2] == 0, y''[-(1/2)] == 0, y''[1/2] == 0}, y[z], z]

$\endgroup$
  • 2
    $\begingroup$ In your code, you use sometimes f[z] and sometimes y[z]. Turn it to the same notation. Besides, using NDSolve you need to fix the boundaries of the interval of integration of your equation. So, fix it. After that go to Menu/Help/WolframDocumentation/NDSolve and have a look at the very first example given there. You will see, how to plot it. $\endgroup$ – Alexei Boulbitch Apr 4 '19 at 7:45
1
$\begingroup$

As Alexei mentioned, you need to name your functions consistently:

sol = NDSolve[
       {f''''[z] + f'''[z] + 1000 f''[z] == 1,
        f[-1/2] == 0, f[1/2] == 0,
        f''[-1/2] == 0, f''[1/2] == 0},
       f, {z, -10, 10}
      ];

Plot[f[x] /. sol, {x, -10, 10}]

Mathematica graphics

| improve this answer | |
$\endgroup$
0
$\begingroup$

DSolve can find an exact solution

Clear["Global`*"]

eqns = {f''''[z] + f'''[z] + 1000 f''[z] == 1, f[-1/2] == 0, f[1/2] == 0, 
   f''[-1/2] == 0, f''[1/2] == 0};

sol = DSolve[eqns, f, z][[1]] //
  ReplacePart[#,
    {-1, -1, -1} -> FullSimplify@#[[-1, -1, -1]]] &

(* {f -> Function[{z}, (1/8000000000)
   E^(1/2 (-1 - z))
     Csc[Sqrt[3999]/4] Sec[Sqrt[3999]/
     4] (Sqrt[3999] E^(
       z/2) (-1 + E - 2 z - 2 E z + 4 Sqrt[E] z Cos[Sqrt[3999]/2]) + 
      2 E^((1 + z)/2) (-251999 + 1000000 z^2) Sin[Sqrt[3999]/2] + 
      2 E^(1/4) (Sqrt[3999] Cos[1/4 Sqrt[3999] (1 - 2 z)] - 
         Sqrt[3999 E] Cos[1/4 Sqrt[3999] (1 + 2 z)] + 
         1999 (Sin[1/4 Sqrt[3999] (1 - 2 z)] + 
            Sqrt[E] Sin[1/4 Sqrt[3999] (1 + 2 z)])))]} *)

Verifying the solution,

And @@ eqns /. sol // Simplify

(* True *)

Plot[f[x] /. sol, {x, -10, 10}]

enter image description here

| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.