Simultaneously setting PlotMarkers and Mesh

Question

ListLinePlot[Table[Sin[x + j], {j, {1, 4}}, {x, 1, 10, 0.1}], 
 PlotMarkers -> {"●", "○", "□", "◇"}, ImageSize -> Medium]

Works but when I introduce Mesh->50 the markers do not change

ListLinePlot[Table[Sin[x + j], {j, {1, 4}}, {x, 1, 10, 0.3}], 
 PlotMarkers -> {"●", "○","□", "◇"}, Mesh -> 30, ImageSize -> Medium]

Answer 1

You can post-process the output of ListLinePlot to modify the Insets:

postProcess[markers_] := Module[{insets, 
    directives = Cases[#, {___, d_Directive, _Line} :> d, All]},
   insets = Inset[#, {0, 0}] & /@ (Style @@@ 
     Transpose[{Take[markers, Length@directives], directives}]); 
   # /. GeometricTransformation[i_, c_] :> 
    (GeometricTransformation @@@ Thread[{insets, Transpose@GatherBy[c, #[[1, 1]] &]}])] &

pmarkers = {"●", "○", "□", "◇"};

ListLinePlot[Table[Sin[x + j], {j, {1, 4}}, {x, 1, 10, 0.1}], 
  PlotMarkers -> pmarkers, ImageSize -> Medium, Mesh -> 30] // 
 postProcess[pmarkers]

Answer 2

I find a simple solution. But sometimes there are wrong shown points. Use Mesh -> {Range[1, 100, 3]} to set the x of mesh points.

ListLinePlot[Table[Sin[x + j], {j, {1, 3, 2, 4}}, {x, 1, 10, 0.1}], PlotMarkers -> {"\[FilledCircle]", "\[EmptyCircle]", "\[EmptySquare]", "\[EmptyDiamond]"}, Mesh -> {Range[1, 100, 3]}, ImageSize -> Medium]