0
$\begingroup$

I have a basic animation of a parametric plot:

a = {6, 1}
b = {2, 1}
c = {-1, -2}
func = Table[
   ParametricPlot3D[{a[[i]] Cos[t] - c[[i]], b[[i]] Sin[t], 0}, {t, 0,
      2 Pi}, PlotRange -> 7], {i, 1, 1}];
Animate[Show[func, 
  Graphics3D[{PointSize[Large], Red, 
Point[Table[{a[[i]] Cos[t] - c[[i]], b[[i]] Sin[t], 0}, {i, 1, 
   1}]]}]], {t, 0, 10}]

Using the parametric equations, I've generated a table of values for the position of the point as it moves around its path at defined intervals.

Table[Labeled[
  TableForm[
   Table[Evaluate[{a[[i]] Cos[t] - c[[i]], b[[i]] Sin[t]}], {t, 0, 
2 Pi, 2 Pi/8}], 
TableHeadings -> {"" Range[0, 2 Pi, 
   2 Pi/8], (ToString[#] <> "") & /@ {{a[[i]] Cos[t] - c[[i]], 
    b[[i]] Sin[t]}}}], {Table}, Top], {i, 1, 1}]

From the code above, I have defined the intervals of time where I want the points coordinates to be shown. I'd like to generate a "real time" table of values for the point which moves around its parametric path which runs alongside the animation. As the point moves around its path, I'd like a table to show the coordinates of the point alongside time.

Would this be possible?

$\endgroup$
  • $\begingroup$ What do you mean by a table of values? Do you just want to show the current coordinates of the point and have those coordinate change as the point moves? Or do you want something where it shows the current coordinates and a set number of past coordinates or something? $\endgroup$ – MassDefect Apr 2 at 3:37
0
$\begingroup$

Something like this:

n = 1;
a = {6, 1};
b = {2, 1};
c = {-1, -2};
func = Table[ParametricPlot3D[{a[[i]] Cos[t] - c[[i]], b[[i]] Sin[t], 0}, {t, 0, 2 Pi}, PlotRange -> 7], {i, 1, n}];
Animate[Row[
  {Show[
    func, 
    Graphics3D[{PointSize[Large], Red, Point[p = Table[{a[[i]] Cos[t] - c[[i]], b[[i]] Sin[t], 0}, {i, 1, n}]]}], ImageSize -> 250],
    Column[{Text["t = " <> ToString[t]],
     TableForm[p, 
      TableHeadings -> {Table["i=" <> ToString[i], {i, 1, n}], {"x", "y", "z"}}]}]
   }, Spacer[5]
  ], {t, 0, 10}]

enter image description here

From the way your code is set up, it looks like you might want to show two trajectories at the same time.

With n=2:

enter image description here

$\endgroup$
  • $\begingroup$ Im not sure if this is an optical illusion, but it seems the larger oval is a circle in three dimensions angled, and your z value is still zero, can this be?, or is that object really only sitting on the xy plane? $\endgroup$ – morbo Apr 2 at 7:28
  • $\begingroup$ @morbo Both functions have z = 0 at all points. The larger ellipse really is an ellipse rather than a circle viewed from an odd angle. $\endgroup$ – MassDefect Apr 2 at 16:06

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.