# Generating a data table from NDSolve solution

Eqn1 = f'''[x] + f[x]*f''[x] - f'[x]*f'[x] + 1 == 0;
Eqn2 = theta''[x] + Pr*(f[x]*theta'[x]) == 0;

BC1 = f[0] == 0;
BC2 =  f'[0] == epsilon;
BC3 = f'[N1] == 1;
BC4 = theta[0] == 1;
BC5 = theta[N1] == 0;

params = {Pr -> 0.7};
N1 = 6; (*N1 is used for infinity. You can test your luck with a HUGE number*)

sol = NDSolve[{Eqn1, Eqn2, BC1, BC2, BC3, BC4, BC5} /. params, {f'', theta}, {x, 0, N1}]

S2 = Table[{epsilon, f''[0]/.sol}, {epsilon, 2,0,0.1}]


I am trying to construct table for the values of f''(0) versus epsilon. But it doesn't work. Please help me. Thanks

You can do it like this,

Eqn1 = f'''[x] + f[x]*f''[x] - f'[x]*f'[x] + 1 == 0;

Eqn2 = theta''[x] + Pr*(f[x]*theta'[x]) == 0;

BC1 = f[0] == 0; BC2 = f'[0] == epsilon; BC3 = f'[N1] == 1; BC4 = theta[0] == 1;

BC5 = theta[N1] == 0;

N1 = 6;

eqns = {Eqn1, Eqn2};

bcs = {BC1, BC2, BC3, BC4, BC5};

Table[{epsilon, f''[0] /. First@NDSolve[Join[eqns /. {Pr -> 0.7}, bcs], {f'', theta'},
{x, 0, N1}]}, {epsilon, 0, 0.5, 0.1}] // TableForm


I would use ParametricNDSolveValue instead:

sol = ParametricNDSolveValue[
{Eqn1,Eqn2,BC1,BC2,BC3,BC4,BC5} /. params,
f''[0],
{x, 0, N1},
epsilon
];

Table[{epsilon, sol[epsilon]}, {epsilon, 0, .5, .1}]


{{0., 0.99593}, {0.1, 0.900199}, {0.2, 1.05113}, {0.3, 0.946816}, {0.4, 0.834072}, {0.5, 0.713295}}

Visualization:

Plot[sol[epsilon], {epsilon, 0, 2}]


Something interesting is going on between .1 and .2.